RELATEDTABLE

Cálculo de la frecuencia de compra de los clientes

admin — Mon, 14 Oct 2019 10:50:28 +0000

Cálculo de la frecuencia de compra de los clientes admin Lun, 14/10/2019 - 12:50

En este escenario partimos de un listado de clientes:

...y de una tabla de compras de cada uno de ellos:

El objetivo es obtener un listado de clientes en el que se muestre el número de días (por ejemplo, podría ser otro período) entre compras. Para hacer el escenario sencillo los clientes reciben como nombre "Cliente x", siendo x el número de compras realizadas (de esta forma, el Cliente 0 no ha realizado ninguna, el Cliente 1 ha realizado una, etc.), y la frecuencia de compra en días para cada cliente coincide también con x. Así, el cliente 2 realizó una primera compra el 3 de enero, y una segunda dos días más tarde, el 5 de enero.

Una vez hemos asegurado que el modelo de datos incluye las relaciones adecuadas (incluyendo una relación entre la tabla de ventas y el necesario calendario), podemos crear una tabla calculada que, usando la función SELECTCOLUMNS, extraiga el listado de clientes y agregue la información necesaria. Partimos, por lo tanto, de la siguiente expresión DAX que define esta primera versión de nuestra tabla de resultados:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre]
)

Aunque podríamos calcular directamente la frecuencia de compra para cada uno de ellos, hagámoslo paso por paso, incluyendo una columna adicional para cada uno de los datos que necesitamos.

Si entendemos por frecuencia de compra el número de días transcurridos entre la primera compra y la última dividido entre el número de compras realizadas, en primer lugar sería preciso calcular las fechas de primera y de última compra por cliente, para lo que vamos a recurrir a las funciones FIRSTDATE y LASTDATE:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre];
"Primera compra"; FIRSTDATE(Calendario[Fecha]);
"Última compra"; LASTDATE(Calendario[Fecha])
)

El cálculo del rango de días entre ambas fechas se reduce a una sencilla resta, que realizaremos usando la función DATEDIFF, función que nos permite especificar el período a considerar -días, en nuestro ejemplo-:

Debemos entender que estamos realizando un enfoque un tanto ingenuo del problema al presuponer que el cliente existe como tal desde su primera compra y solo hasta la última. Más realista sería considerar como comienzo del período el día en el que el cliente "se dio de alta como tal", hubiese realizado o no una compra, y/o considerar como fin del período el día actual, por ejemplo.

Considérese también que, al crearse la tabla calculada en un entorno de contexto de fila, para cada cliente se extrae la información de la tabla remota relacionada con él. Así, cuando se está calculando la primera fecha de compra para el cliente X, la expresión

FIRSTDATE(Calendario[Fecha])

...filtra el campo Fecha de la tabla Calendario de forma que solo incluya las fechas para las que existen compras asociadas al cliente que corresponda.

El siguiente paso es contar el número de compras por cliente, para lo que podemos extraer la tabla Ventas (una vez filtrada por el contexto, para lo que usaremos la función RELATEDTABLE) y contar el número de filas que tiene con COUNTROWS:

Por último queda lo más sencillo, que es dividir el rango de fechas entre el número de compras, para lo que recurriremos a la función DIVIDE:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre];
"Primera compra"; FIRSTDATE(Calendario[Fecha]);
"Última compra"; LASTDATE(Calendario[Fecha]);
"Rango"; DATEDIFF(FIRSTDATE(Calendario[Fecha]); LASTDATE(Calendario[Fecha]); DAY);
"Nº de compras"; COUNTROWS(RELATEDTABLE(Ventas));
"Frecuencia de compra"; DIVIDE(
DATEDIFF(FIRSTDATE(Calendario[Fecha]); LASTDATE(Calendario[Fecha]); DAY);
COUNTROWS(RELATEDTABLE(Ventas))
)
)

Comprobamos que, en esta primera versión de la expresión, si un cliente no ha realizado ninguna compra se muestra un BLANK, y si ha realizado una única compra de devuelve una frecuencia de 1. Podríamos completar nuestro DIVIDE con alguna función lógica que realizase un cálculo u otro en función del número de compras y, de esta forma, gestionar estas excepciones.

Puede descargarse el fichero Excel y el informe Power BI resultante aquí.

Funciones DAX involucradas

Dificultad

Intermedia

Marcado de días como laborables o no laborables

admin — Sun, 14 Jul 2019 07:20:08 +0000

Marcado de días como laborables o no laborables admin Dom, 14/07/2019 - 09:20

La adición de esta información a nuestra tabla de calendario -si cada uno de los días es o no laborable- puede resultar de gran utilidad de muchos casos. Planteémonos, en primer lugar, el caso más sencillo: el marcado de cada uno de los días en función del día de la semana de que se trate. Es decir, marquemos como laborables los días entre el lunes y el viernes, ambos incluidos, y como no laborables el sábado y el domingo. Para ello vamos a utilizar la función WEEKDAY que acepta como argumento una fecha y devuelve un número identificando el día de la semana correspondiente.

Partimos de una tabla "Calendar" que incluye únicamente una columna con las fechas:

Creamos una nueva columna calculada en la que extraemos el número de día de la semana:

Nº de día de la semana =
WEEKDAY('Calendar'[Date];2)

En este caso se ha optado por la opción 2 (de las tres que se ofrecen), opción que asigna el valor 1 al lunes y el 7 al domingo:

Podemos comparar los nombres de los días de la semana que se muestran en la función Date con el valor mostrado en la columna recién creada para confirmar que el criterio es el comentado. Así, por ejemplo, la primera fecha mostrada en la del jueves 1 de enero de 2015, día al que se asigna correctamente el valor 4 en la recién creada columna calculada.

En realidad no hubiera sido necesario crear esta columna, apenas nos sirve para confirmar los valores que reciben cada uno de los días. Lo que sí es necesario en la creación de una columna -a la que podemos llamar Día laboral- que, por ejemplo, contenga el booleano TRUE cuando el día sea laboral, y el booleano FALSE cuando no lo sea. Y para esta asignación vamos a comparar el valor numérico asignado por la función WEEKDAY a cada uno de los días: cuando tome los valores 1, 2, 3, 4 o 5, se asignará el valor TRUE, y cuando tome los valores 6 o 7, FALSE. Lógicamente estos valores son los correctos solo si estamos usando la función WEEKDAY con la mencionada opción 2. Si escogiésemos otra opción, habría que escoger las cifras adecuadamente:

Día laboral =
IF(
WEEKDAY('Calendar'[Date]; 2) < 6;
TRUE();
FALSE()
)

En un segundo paso, si quisiéramos añadir como días no laborables otras festividades, podríamos recurrir a mantener otra tabla con este listado. Por ejemplo, supongamos que las fechas no laborables adicionales son las mostradas en la siguiente tabla ("Festivos"):

Relacionamos ambas tablas:

Y, a continuación, modificamos el código que hemos creado de forma que asigne el valor TRUE si y solo si el número de día es menor que 6 y no aparece en la tabla de festivos. Esta última condición puede ser escrita de diversas maneras. Por ejemplo, contando el número de filas de la tabla Festivos asociada a cada fecha del calendario: cuando la fecha en cuestión no esté incluida en Festivos, esta tabla no contendrá ningún registro. Y cuando esté, tendrá uno:

Día laboral =
IF(
WEEKDAY('Calendar'[Date]; 2) < 6 && COUNTROWS(RELATEDTABLE(Festivos)) = 0;
TRUE();
FALSE()
)

El resultado es el mostrado en la siguiente imagen:

Podemos ver que los días 6 y 13 de enero han sido marcados como "no laborables", tal y como esperábamos.

Por supuesto, este escenario podría hacerse más complejo para mostrar diferentes columnas para diferentes localidades o países, etc.

Funciones DAX involucradas

Creación de una tabla con las ventas medias por vendedor

admin — Sun, 07 Apr 2019 12:50:59 +0000

Creación de una tabla con las ventas medias por vendedor admin Dom, 07/04/2019 - 14:50

En este escenario partimos de dos tablas:

DimEmployee, conteniendo información sobre los empleados. Esta tabla contiene el campo Name con el nombre completo de cada vendedor, y el campo SalesTerritoryKey, con el territorio de ventas asignado a cada empleado. Hay 10 territorios de ventas (de 1 a 10). Los empleados que no trabajan en ventas reciben un SalesTerritoryKey de 11.
FactResellerSales, conteniendo información sobre las ventas realizadas. Esta tabla contiene el campo SalesAmount con el precio de venta (de cada una de las ventas) y está enlazada con la anterior a través de un campo EmployeeKey.

El objetivo es la creación de una tabla calculada en la que se muestren tres campos: el nombre de cada vendedor, su territorio de ventas y la cifra media de ventas de cada uno.

Para la creación de la tabla vamos a utilizar la función SELECTCOLUMNS a partir de la tabla de empleados, extrayendo el nombre de los empleados que nos interesan, su territorio, y añadiendo su cifra media de ventas. En pseudo-código sería:

Average sales amount per seller = SELECTCOLUMNS(
DimEmployee;
"Name"; <nombre de cada empleado de ventas>;
"Territory"; <territorio de cada empleado>;
"Average sales"; Cálculo-de-ventas-medias
)

Como primer intento, vamos a calculas las ventas medias usando la función AVERAGE para calcular el valor medio de la columna SalesAmount. El código sería el siguiente:

Average sales amount per seller =
SELECTCOLUMNS(
DimEmployee;
"Name"; DimEmployee[Name];
"Territory"; DimEmployee[SalesTerritoryKey];
"Average sales"; AVERAGE(FactResellerSales[SalesAmount])
)

Y el resultado:

Vemos dos errores: se están mostrando empleados que no pertenecen a ventas (cuyo territorio es el 11) y todas las cifras medias de ventas son iguales, señal de que no estamos personalizando el cálculo para cada vendedor. Arreglemos en primer lugar el primer problema: debemos considerar solo los empleados cuyo territorio de ventas no sea 11. En el código usado vemos que estamos partiendo de la tabla DimEmployee para extraer el nombre, etc. Podemos partir, no de esta tabla completa, sino de la tabla filtrada usando la función FILTER, de forma que solo se incluyan los vendedores:

Average sales amount per seller =
SELECTCOLUMNS(
FILTER(
DimEmployee;
DimEmployee[SalesTerritoryKey] <> 11
);
"Name"; DimEmployee[Name];
"Territory"; DimEmployee[SalesTerritoryKey];
"Average sales"; AVERAGE(FactResellerSales[SalesAmount])
)

El resultado en este caso es el siguiente:

...lo que tiene mucho mejor aspecto. Al respecto del segundo problema -que las cifras devueltas por la función AVERAGE sean las mismas, debemos entender que esta función está considerando toda la tabla de ventas para hacer el cálculo. Tenemos que filtrar esta tabla para que solo considere las ventas de cada empleado. Para ello podemos usar la función RELATEDTABLE que cambia el contexto en el que se va a realizar el cálculo filtrando la tabla de ventas de forma que solo se considere el subconjunto de esta tabla que esté relacionado con la fila (con el vendedor) siendo considerada. Es decir, para el primer vendedor que vemos en la imagen anterior, Michael Blythe, la función RELATEDTABLE filtraría la tabla de ventas extrayendo solo las ventas en las que Michael aparezca como vendedor asociado a la venta. Pero la función AVERAGE no admite una tabla como argumento... Afortunadamente podemos recurrir a la función AVERAGEX que acepta una tabla como primer argumento y una expresión como segundo (que puede ser simplemente el campo SalesAmount que nos interesa):

Ahora el resultado es el correcto:

Funciones DAX involucradas