SELECTCOLUMNS

Cálculo de la frecuencia de compra de los clientes

admin — Mon, 14 Oct 2019 10:50:28 +0000

Cálculo de la frecuencia de compra de los clientes admin Lun, 14/10/2019 - 12:50

En este escenario partimos de un listado de clientes:

...y de una tabla de compras de cada uno de ellos:

El objetivo es obtener un listado de clientes en el que se muestre el número de días (por ejemplo, podría ser otro período) entre compras. Para hacer el escenario sencillo los clientes reciben como nombre "Cliente x", siendo x el número de compras realizadas (de esta forma, el Cliente 0 no ha realizado ninguna, el Cliente 1 ha realizado una, etc.), y la frecuencia de compra en días para cada cliente coincide también con x. Así, el cliente 2 realizó una primera compra el 3 de enero, y una segunda dos días más tarde, el 5 de enero.

Una vez hemos asegurado que el modelo de datos incluye las relaciones adecuadas (incluyendo una relación entre la tabla de ventas y el necesario calendario), podemos crear una tabla calculada que, usando la función SELECTCOLUMNS, extraiga el listado de clientes y agregue la información necesaria. Partimos, por lo tanto, de la siguiente expresión DAX que define esta primera versión de nuestra tabla de resultados:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre]
)

Aunque podríamos calcular directamente la frecuencia de compra para cada uno de ellos, hagámoslo paso por paso, incluyendo una columna adicional para cada uno de los datos que necesitamos.

Si entendemos por frecuencia de compra el número de días transcurridos entre la primera compra y la última dividido entre el número de compras realizadas, en primer lugar sería preciso calcular las fechas de primera y de última compra por cliente, para lo que vamos a recurrir a las funciones FIRSTDATE y LASTDATE:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre];
"Primera compra"; FIRSTDATE(Calendario[Fecha]);
"Última compra"; LASTDATE(Calendario[Fecha])
)

El cálculo del rango de días entre ambas fechas se reduce a una sencilla resta, que realizaremos usando la función DATEDIFF, función que nos permite especificar el período a considerar -días, en nuestro ejemplo-:

Debemos entender que estamos realizando un enfoque un tanto ingenuo del problema al presuponer que el cliente existe como tal desde su primera compra y solo hasta la última. Más realista sería considerar como comienzo del período el día en el que el cliente "se dio de alta como tal", hubiese realizado o no una compra, y/o considerar como fin del período el día actual, por ejemplo.

Considérese también que, al crearse la tabla calculada en un entorno de contexto de fila, para cada cliente se extrae la información de la tabla remota relacionada con él. Así, cuando se está calculando la primera fecha de compra para el cliente X, la expresión

FIRSTDATE(Calendario[Fecha])

...filtra el campo Fecha de la tabla Calendario de forma que solo incluya las fechas para las que existen compras asociadas al cliente que corresponda.

El siguiente paso es contar el número de compras por cliente, para lo que podemos extraer la tabla Ventas (una vez filtrada por el contexto, para lo que usaremos la función RELATEDTABLE) y contar el número de filas que tiene con COUNTROWS:

Por último queda lo más sencillo, que es dividir el rango de fechas entre el número de compras, para lo que recurriremos a la función DIVIDE:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre];
"Primera compra"; FIRSTDATE(Calendario[Fecha]);
"Última compra"; LASTDATE(Calendario[Fecha]);
"Rango"; DATEDIFF(FIRSTDATE(Calendario[Fecha]); LASTDATE(Calendario[Fecha]); DAY);
"Nº de compras"; COUNTROWS(RELATEDTABLE(Ventas));
"Frecuencia de compra"; DIVIDE(
DATEDIFF(FIRSTDATE(Calendario[Fecha]); LASTDATE(Calendario[Fecha]); DAY);
COUNTROWS(RELATEDTABLE(Ventas))
)
)

Comprobamos que, en esta primera versión de la expresión, si un cliente no ha realizado ninguna compra se muestra un BLANK, y si ha realizado una única compra de devuelve una frecuencia de 1. Podríamos completar nuestro DIVIDE con alguna función lógica que realizase un cálculo u otro en función del número de compras y, de esta forma, gestionar estas excepciones.

Puede descargarse el fichero Excel y el informe Power BI resultante aquí.

Funciones DAX involucradas

Dificultad

Intermedia

Generación de una tabla con una columna de valores aleatorios

admin — Sun, 14 Jul 2019 10:09:52 +0000

Generación de una tabla con una columna de valores aleatorios admin Dom, 14/07/2019 - 12:09

En ocasiones queremos generar valores aleatorios para plantear diferentes escenarios de análisis. Generar un único valor es sencillo usando las funciones RAND o RANDBETWEEN, pero la generación de un listado de valores aleatorios es un poco más complicado. En este escenario queremos crear una tabla con una columna de valores enteros aleatorios.

La generación de una tabla con una columna de n filas es sencillo si utilizamos la función GENERATESERIES. Por ejemplo, para generar 10 valores (consecutivos) podemos recurrir al siguiente código:

Tabla = GENERATESERIES(1; 10)

Una vez generada la tabla con el número de filas que nos interesa, añadir columnas con contenido personalizado es muy sencillo con la función SELECTCOLUMNS. Podemos, por ejemplo, incluir una nueva columna en la que se generen los números aleatorios que estamos buscando, ignorando la columna Value que ya existe:

Tabla =
SELECTCOLUMNS(
GENERATESERIES(1; 10);
"Value"; RANDBETWEEN(1; 5)
)

Si quisiéramos generar valores reales, podemos usar la función RAND:

Tabla FLOAT =
SELECTCOLUMNS(
GENERATESERIES(1; 10);
"Value"; RAND()
)

Funciones DAX involucradas

Cálculo del número de días entre compras

admin — Tue, 02 Jul 2019 14:23:33 +0000

Cálculo del número de días entre compras admin Mar, 02/07/2019 - 16:23

Partimos de un listado de ventas (Sales) en el que se indica -por ejemplo- el identificador de cliente y las fechas de las compras:

El objetivo es añadir a esta tabla una columna que indique el número de días transcurridos desde la compra anterior (anterior en el tiempo, pues nada nos asegura que el orden de los datos en la tabla original sea cronológico, y ya sabemos que Power BI tampoco asegura el orden de las filas).

La resolución de este escenario no es sencilla. Aun cuando podría resolverse en una única expresión, se plantea a continuación su resolución paso a paso. Las fases involucradas son las siguientes:

Es necesario obtener, para cada fecha de compra del cliente X, la fecha de la anterior compra.
La anterior fecha de compra es la mayor fecha de todas las compras del cliente X (exceptuando la compra que estemos analizando, por supuesto).
Podemos obtener todas las compras anteriores del cliente X realizando una combinación cruzada de la tabla consigo misma tomando como campo común el correspondiente al identificador del cliente y considerando en la tabla de la derecha (véase la documentación de la función GENERATE) solo las fechas anteriores a la de la fecha de compra siendo considerada en la tabla izquierda. Así, por ejemplo, para la compra que aparece en la tercera línea de la imagen anterior (correspondiente al cliente 1, con fecha de 21 de enero de 2019), una combinación cruzada con la misma tabla en las condiciones mencionadas devolvería una fila para la combinación de la fila 3 y la fila 1 (mismo cliente y fecha anterior) y otra para la combinación de la fila 3 y la fila 2 (de nuevo, mismo cliente y fecha anterior).

Por último, una vez obtenida la tabla mencionada en el punto 1, bastaría calcular la diferencia entre cada fecha de compra y la fecha de la última compra.

Vamos punto por punto.

En primer lugar queremos obtener, para cada fila (es decir, para cada compra), el conjunto de compras anteriores del mismo cliente. Esto, como se ha comentado, puede lograrse con una combinación cruzada que nos permita especificar las condiciones de la combinación, es decir, con la función GENERATE. Como esta función requiere que las tablas involucradas en la combinación tengan campos con nombres diferentes, vamos modificar los nombres de los campos de la segunda copia con la función SELECTCOLUMNS, añadiendo un símbolo "_" al final de los nombres:

SelfJoin =
GENERATE(
Sales;
FILTER(
SELECTCOLUMNS(
Sales;
"Customer_"; Sales[Customer];
"Purchase Date_"; Sales[Purchase Date]
);
[Purchase Date_] < Sales[Purchase Date] && Sales[Customer] = [Customer_]
)
)

Tal y como se ve, estamos obteniendo la combinación cruzada imponiendo la condición de que el identificador de cliente sea el mismo, y que las fechas de la columna de la derecha sean inferiores a la fecha considerada en cada una de las filas de la izquierda (para simplificar, estamos suponiendo que un mismo cliente no va a realizar dos compras el mismo día).

Obsérvese que no aparecen los registros de la primera tabla para los que no hay registros en la segunda que cumplan las condiciones impuestas (es decir, en la tabla que acabamos de crear, solo se incluyen fechas de compra para las que hay alguna compra anterior).

Obtener, a partir de aquí, la fecha anterior a cada compra es fácil: basta con agrupar (con la función GROUPBY) por cliente y fecha de compra (campos Customer y Purchase Date) y seleccionar el valor máximo (de cada grupo) del campo Purchase Date_:

LastPurchases =
GROUPBY(
SelfJoin;
SelfJoin[Customer];
SelfJoin[Purchase Date];
"Last Purchase"; MAXX(
CURRENTGROUP();
SelfJoin[Purchase Date_]
)
)

Ahora viene un proceso un tanto complicado: como en la tabla solo se incluyen fechas de compra para las que existe una compra anterior, para que en el resultado final aparezcan todas las fechas originales tendríamos que realizar una combinación externa izquierda entre la tabla de fechas original y la nueva. Para esto tendríamos que usar la función NATURALLEFTOUTERJOIN, pero esta función exige que las tablas a combinar tengan la misma ascendencia (procedan de la misma fuente), lo que no se cumple en nuestro caso. Tal y como se explica en la documentación de esta función, es posible resolver este problema añadiendo una cadena de texto vacía al final de los nombres:

Purchase and Last Purchase =
NATURALLEFTOUTERJOIN(
SELECTCOLUMNS(
Sales;
"Customer"; Sales[Customer] & "";
"Purchase Date"; Sales[Purchase Date] & ""
);
SELECTCOLUMNS(
LastPurchases;
"Customer"; LastPurchases[SelfJoin_Customer] & "";
"Purchase Date"; LastPurchases[SelfJoin_Purchase Date] & "";
"Last Purchase"; LastPurchases[Last Purchase]
)
)

Por último, para calcular el número de días desde la última compra basta con añadir una nueva columna que devuelva la diferencia (solo si existe una última compra):

Days since last purchase =
ADDCOLUMNS(
'Purchase and Last Purchase';
"# days";
VAR
NumberOfDays =
'Purchase and Last Purchase'[Purchase Date] -
'Purchase and Last Purchase'[Last Purchase]
RETURN
IF(
ISBLANK('Purchase and Last Purchase'[Last Purchase]);
BLANK();
NumberOfDays
)
)

Para devolver la diferencia de días comentada utilizamos la función IF para confirmar si el valor del campo correspondiente a la última compra es un BLANK o no, para lo que utilizamos la función ISBLANK.

Funciones DAX involucradas

Dificultad

Alta

Replicación de cada fila de una tabla según una tabla de valores

admin — Tue, 02 Jul 2019 09:25:51 +0000

Replicación de cada fila de una tabla según una tabla de valores admin Mar, 02/07/2019 - 11:25

Otra aplicación interesante de la función GENERATE es la de replicar las filas de una tabla según ciertos valores. Por ejemplo, supongamos que tenemos una tabla de ventas ("Ventas") en las que se muestra el producto vendido y el número de unidades implicadas en cada venta:

En múltiples circunstancias preferiríamos tener, no este tipo de listado, sino aquel en el que el item C, por ejemplo, aparezca tantas veces (en tantas filas) como unidades se han vendido (es decir, en el que aparezca tres veces en nuestro ejemplo).

Este escenario podría ser resuelto si consiguiésemos realizar una combinación cruzada entre cada una de las filas de la tabla anterior y una tabla de soporte que tuviese tantas filas como se indicase en el campo Units de Ventas (con independencia del contenido exacto que tuviese esta tabla de soporte). Es posible crear una tabla con n filas mediante la función GENERATESERIES, función que crea una tabla con una única columna de nombre Value con los valores de una progresión aritmética. Es decir, si el número de unidades del producto C -por ejemplo- es 3, la combinación cruzada de dicha fila con el resultado de GENERATESERIES(1; 3) estaría replicando la fila del producto C tres veces.

Afortunadamente ya sabemos que la función GENERATE genera un contexto de filtro para cada una de las filas de la primera tabla, lo que significa que los datos de dicha fila están a disposición de la segunda (y que, de hecho, esta segunda tabla se va a contextualizar según dicho contexto). En otras palabras, el campo Units está disponible para la segunda tabla de la función GENERATE.

Todo esto hace muy fácil conseguir el resultado buscado, pues basta con ejecutar el siguiente código para generar la tabla que queremos:

Tabla =
GENERATE(
Ventas;
GENERATESERIES(1; Ventas[Units])
)

La función GENERATE va a recorrer cada fila de la tabla Ventas, creando el contexto de fila asociado a cada una y a realizar una combinación cruzada con todas las filas de la segunda tabla tras contextualizar esta última. La segunda tabla es el resultado de generar una progresión aritmética entre 1 y el valor del campo Units (disponible vía contexto de fila, de forma que basta con hacer referencia al nombre del campo para acceder a su contenido).

Si quisiéramos quedarnos ahora con apenas los campos Id y Product (por ejemplo), bastaría utilizar la función SELECTCOLUMNS:

Tabla =
SELECTCOLUMNS(
GENERATE(
Ventas;
GENERATESERIES(1; Ventas[Units])
);
"Id"; Ventas[Id];
"Product"; Ventas[Product]
)

Funciones DAX involucradas

GENERATE

GENERATESERIES

SELECTCOLUMNS

Visualización de los días de ocupación de un recurso

admin — Mon, 01 Jul 2019 16:38:30 +0000

Visualización de los días de ocupación de un recurso admin Lun, 01/07/2019 - 18:38

Un interesante escenario es aquel que implica una tabla de datos que incluye la "ocupación" de unos ciertos recursos indicando la fecha de comienzo y la de finalización de la ocupación, teniendo como objetivo la visualización de una gráfica en la que se muestre el calendario y los días en los que cada recurso está ocupado o disponible.

Para resolver este escenario partimos de una tabla ("Allocations") en la que se muestra el recurso en cuestión (1, 2 o 3 en nuestro ejemplo), y las fechas de inicio y fin de la ocupación:

Partimos también de un calendario ("Calendar") que, en este ejemplo, está limitado a la quincena dentro de la cual se producen las ocupaciones de cada recurso:

Si generamos un gráfico a mano -usando Excel, por ejemplo-, la visualización de las ocupaciones de cada recurso tendría el siguiente aspecto:

El objetivo es llegar a una visualización semejante que se genere de forma automática.

Obsérvese que si cruzamos la tabla "Allocations" (que incluye los períodos en los que cada recurso está reservado) y el calendario mediante la función GENERATE, por ejemplo (también valdría la función CROSSJOIN pues, en este caso, no estamos haciendo uso del contexto de fila generado por las filas de la primera tabla), tendremos todas las posibles combinaciones entre las filas de ambas:

Table =
GENERATE(
Allocations;
'Calendar'
)

Y de esta tabla, es sencillo quedarnos solo con los días en los que el recurso está reservado si seleccionamos apenas aquellas filas en las que el campo Date sea mayor o igual a Start y menor o igual a End, para lo que recurrimos a la función FILTER:

Table =
FILTER(
GENERATE(
Allocations;
'Calendar'
);
'Calendar'[Date] >= Allocations[Start] && 'Calendar'[Date] <= Allocations[End]
)

En este punto podríamos obviar los campos Start y End, que ya no aportan nada, para lo que podemos recurrir a la función SELECTCOLUMNS que nos permite escoger qué campos queremos seleccionar:

Table =
SELECTCOLUMNS(
FILTER(
GENERATE(
Allocations;
'Calendar'
);
'Calendar'[Date] >= Allocations[Start] && 'Calendar'[Date] <= Allocations[End]
);
"Id"; Allocations[Id];
"Resource"; Allocations[Resource];
"Date"; 'Calendar'[Date]
)

Para visualizar el resultado vamos a recurrir a la visualización "as Timeline" descargable desde el marketplace. Una vez llevada al lienzo su configuración es la siguiente:

Y la visualización queda de la siguiente forma:

Podemos comparar el resultado con el esquema realizado a mano:

También habríamos podido aprovechar el contexto de fila creado por la función GENERATE para incluir el filtro dentro de la propia función, de la siguiente manera:

Table =
SELECTCOLUMNS(
GENERATE(
Allocations;
FILTER(
'Calendar';
'Calendar'[Date] >= Allocations[Start] && 'Calendar'[Date] <= Allocations[End]
)
);
"Id"; Allocations[Id];
"Resource"; Allocations[Resource];
"Date"; 'Calendar'[Date]
)

Funciones DAX involucradas

Renombrado de los campos de una tabla

admin — Mon, 01 Jul 2019 16:12:31 +0000

Renombrado de los campos de una tabla admin Lun, 01/07/2019 - 18:12

Hay múltiples ocasiones en las que resulta conveniente -o necesario- renombrar temporalmente los campos de una tabla antes de poder utilizarla en una expresión DAX. Esto puede lograrse fácilmente utilizando la función SELECTCOLUMNS. Veámos un sencillo ejemplo: Partimos de la siguiente tabla:

Ahora deseamos crear una versión de esta tabla en la que los nombres de los campos aparezcan... en inglés, por ejemplo, con el fin de realizar una combinación con otra tabla o por el motivo que sea. En este ejemplo vamos a crear una nueva tabla, y lo hacemos con la función SELECTCOLUMNS, e incluyendo todos los campos con los nombres que nos convengan:

Tabla2 =
SELECTCOLUMNS(
Tabla;
"Office"; Tabla[Oficina];
"Year"; Tabla[Año];
"Sales"; Tabla[Ventas]
)

Funciones DAX involucradas

SELECTCOLUMNS

Agregación de dos tablas con la misma estructura

admin — Wed, 10 Apr 2019 08:58:12 +0000

Agregación de dos tablas con la misma estructura admin Mié, 10/04/2019 - 10:58

Un escenario frecuente y sencillo de resolver es aquel en el que nos encontramos con dos tablas de idéntica estructura que deseamos agregar según algún campo. Veamos cómo sería. Suponemos que ya hemos obtenido los datos y tenemos cargadas en Power BI las dos tablas que, en este caso, contienen información de ventas:

En este escenario queremos obtener el total de ventas por vendedor. Vamos a hacerlo en dos fases:

Unión de las tablas anteriores
Agregación de la tabla completa para mostrar las ventas (campo "Precio final") según el campo que identifica cada vendedor

Para el primer paso vamos a recurrir a la función UNION. Sin embargo, no vamos a unir las tablas directamente pues, como vemos en las imágenes anteriores, a pesar de tener la misma estructura (y, en el editor de consultas, aparecer con las columnas en el mismo orden) cuando se importan a Power BI las columnas no se muestran en el mismo orden (probablemente por un bug en el software que existe desde, al menos, finales de 2017). Es por ello que vamos a aplicar la función UNION a las tablas especificando a mano las columnas que nos interesan y el orden que nos interesa, para lo que recurriremos a la función SELECTCOLUMNS:

Ventas totales =
VAR
Tabla1 = SELECTCOLUMNS(
Ventas1;
"Vendedor"; Ventas1[Id Vendedor];
"PVP"; Ventas1[Precio final]
)
VAR
Tabla2 = SELECTCOLUMNS(
Ventas2;
"Vendedor"; Ventas2[Id Vendedor];
"PVP"; Ventas2[Precio final]
)
RETURN
UNION(Tabla1; Tabla2)

Hemos seleccionado apenas las columnas "Vendedor" y "Precio final" (con el nombre de "PVP") pero podríamos haber seleccionado otras columnas también.

Ahora, para el segundo paso, utilizamos la función SUMMARIZE para agregar la tabla anterior:

Ventas totales por vendedor =
SUMMARIZE(
'Ventas totales';
'Ventas totales'[Vendedor];
"Ventas"; SUM('Ventas totales'[PVP]
)
)

Funciones DAX involucradas

Dificultad

Intermedia

Recuento del número de valores distintos de una columna

admin — Tue, 09 Apr 2019 09:29:53 +0000

Recuento del número de valores distintos de una columna admin Mar, 09/04/2019 - 11:29

En este sencillo escenario partimos de dos tablas:

Productos. Tabla de dimensiones conteniendo dos campos, con un identificador de cada producto y el nombre del producto. Vemos que hay 6 productos cuyos identificadores pertenecen al rango [1, 6]:

Ventas: Tabla de hechos con una única columna conteniendo los identificadores de los productos vendidos. Podemos apreciar la existencia de una fila con el identificador 7 que no existe en la tabla de dimensiones anterior, lo que provoca una violación de integridad referencial:

Si creamos una tabla calculada con los identificadores de los productos vendidos y su nombre (extraído de la tabla producto), el resultado es el siguiente:

Productos vendidos = SELECTCOLUMNS(
Ventas;
"Id. Producto"; Ventas[Id Producto];
"Nombre"; RELATED(Productos[Nombre de producto])
)

Para acceder a la columna "Nombre de producto" de la tabla "Productos" utilizamos la función RELATED que nos da acceso a una columna remota.

Vemos que el producto con identificador 7 no tiene un nombre asociado. Si quisiéramos contar el número de productos vendidos distintos y para ello utilizásemos la segunda columna de la tabla anterior (la que ha recibido el nombre de "Nombre"), podríamos hacerlo con dos funciones distintas: DISTINCTCOUNT y DISTINCTCOUNTNOBLANK. Si definimos dos medidas con estas funciones, tenemos lo siguiente (damos a las medidas el mismo nombre de la función usada en cada caso):

DISTINCTCOUNTNOBLANK = DISTINCTCOUNTNOBLANK('Productos vendidos'[Nombre])

DISTINCTCOUNT = DISTINCTCOUNT('Productos vendidos'[Nombre])

Si llevamos estas medidas a dos visualizaciones tipo tarjeta, tenemos:

Comprobamos que la función DISTINCTCOUNT cuenta el número de valores distintos considerando los valores vacíos (BLANK) como un valor adicional, mientras que DISTINCTCOUNTNOBLANK excluye estos valores vacíos.

Funciones DAX involucradas

SELECTCOLUMNS

DISTINCTCOUNT

DISTINCTCOUNTNOBLANK

Obtención de la fecha de la primera y última venta de cada vendedor

admin — Mon, 08 Apr 2019 09:50:20 +0000

Obtención de la fecha de la primera y última venta de cada vendedor admin Lun, 08/04/2019 - 11:50

En este sencillo escenario partimos de los siguientes datos:

Tabla de vendedores:

Tabla de ventas:

El objetivo es crear una tabla calculada en la que se incluya el nombre del vendedor y las fechas de su primera y última venta. Comencemos creando la tabla con los nombres, para lo que vamos a usar la función SELECTCOLUMNS:

Listado vendedores = SELECTCOLUMNS(
Vendedores;
"Nombre"; Vendedores[Nombre Vendedor]
)

Añadamos ahora la columna con la primera fecha de venta. Podríamos pensar en la necesidad de extraer mediante la función RELATEDTABLE el subconjunto de la tabla de ventas asociada a cada fila de nuestra tabla (tal y como hacemos en el escenario de Creación de una tabla con las ventas medias por vendedor) pero la función FIRSTDATE, tal y como podemos leer en la documentación, devuelve la primera fecha en el contexto actual, lo que supone el contexto de fila definido por cada vendedor, en nuestro caso, lo que hace innecesario el uso de la mencionada función RELATEDTABLE. Basta con usar FIRSTDATE de la siguiente forma:

Listado vendedores = SELECTCOLUMNS(
Vendedores;
"Nombre"; Vendedores[Nombre Vendedor];
"Primera venta"; FIRSTDATE(Ventas[Fecha])
)

Vemos que las fechas son distintas, lo que ya nos indica que el cálculo de FIRSTDATE se realiza en contextos diferentes para cada fila. En todo caso comprobamos mediante una inspección ocular de la tabla de ventas que las fechas mostradas son las correctas.

La adición de la última fecha de venta es análoga, utilizando la función LASTDATE:

Listado vendedores = SELECTCOLUMNS(
Vendedores;
"Nombre"; Vendedores[Nombre Vendedor];
"Primera venta"; FIRSTDATE(Ventas[Fecha]);
"Última venta"; LASTDATE(Ventas[Fecha])
)

Funciones DAX involucradas

SELECTCOLUMNS

FIRSTDATE

LASTDATE

Creación de una tabla con las ventas medias por vendedor

admin — Sun, 07 Apr 2019 12:50:59 +0000

Creación de una tabla con las ventas medias por vendedor admin Dom, 07/04/2019 - 14:50

En este escenario partimos de dos tablas:

DimEmployee, conteniendo información sobre los empleados. Esta tabla contiene el campo Name con el nombre completo de cada vendedor, y el campo SalesTerritoryKey, con el territorio de ventas asignado a cada empleado. Hay 10 territorios de ventas (de 1 a 10). Los empleados que no trabajan en ventas reciben un SalesTerritoryKey de 11.
FactResellerSales, conteniendo información sobre las ventas realizadas. Esta tabla contiene el campo SalesAmount con el precio de venta (de cada una de las ventas) y está enlazada con la anterior a través de un campo EmployeeKey.

El objetivo es la creación de una tabla calculada en la que se muestren tres campos: el nombre de cada vendedor, su territorio de ventas y la cifra media de ventas de cada uno.

Para la creación de la tabla vamos a utilizar la función SELECTCOLUMNS a partir de la tabla de empleados, extrayendo el nombre de los empleados que nos interesan, su territorio, y añadiendo su cifra media de ventas. En pseudo-código sería:

Average sales amount per seller = SELECTCOLUMNS(
DimEmployee;
"Name"; <nombre de cada empleado de ventas>;
"Territory"; <territorio de cada empleado>;
"Average sales"; Cálculo-de-ventas-medias
)

Como primer intento, vamos a calculas las ventas medias usando la función AVERAGE para calcular el valor medio de la columna SalesAmount. El código sería el siguiente:

Average sales amount per seller =
SELECTCOLUMNS(
DimEmployee;
"Name"; DimEmployee[Name];
"Territory"; DimEmployee[SalesTerritoryKey];
"Average sales"; AVERAGE(FactResellerSales[SalesAmount])
)

Y el resultado:

Vemos dos errores: se están mostrando empleados que no pertenecen a ventas (cuyo territorio es el 11) y todas las cifras medias de ventas son iguales, señal de que no estamos personalizando el cálculo para cada vendedor. Arreglemos en primer lugar el primer problema: debemos considerar solo los empleados cuyo territorio de ventas no sea 11. En el código usado vemos que estamos partiendo de la tabla DimEmployee para extraer el nombre, etc. Podemos partir, no de esta tabla completa, sino de la tabla filtrada usando la función FILTER, de forma que solo se incluyan los vendedores:

Average sales amount per seller =
SELECTCOLUMNS(
FILTER(
DimEmployee;
DimEmployee[SalesTerritoryKey] <> 11
);
"Name"; DimEmployee[Name];
"Territory"; DimEmployee[SalesTerritoryKey];
"Average sales"; AVERAGE(FactResellerSales[SalesAmount])
)

El resultado en este caso es el siguiente:

...lo que tiene mucho mejor aspecto. Al respecto del segundo problema -que las cifras devueltas por la función AVERAGE sean las mismas, debemos entender que esta función está considerando toda la tabla de ventas para hacer el cálculo. Tenemos que filtrar esta tabla para que solo considere las ventas de cada empleado. Para ello podemos usar la función RELATEDTABLE que cambia el contexto en el que se va a realizar el cálculo filtrando la tabla de ventas de forma que solo se considere el subconjunto de esta tabla que esté relacionado con la fila (con el vendedor) siendo considerada. Es decir, para el primer vendedor que vemos en la imagen anterior, Michael Blythe, la función RELATEDTABLE filtraría la tabla de ventas extrayendo solo las ventas en las que Michael aparezca como vendedor asociado a la venta. Pero la función AVERAGE no admite una tabla como argumento... Afortunadamente podemos recurrir a la función AVERAGEX que acepta una tabla como primer argumento y una expresión como segundo (que puede ser simplemente el campo SalesAmount que nos interesa):

Ahora el resultado es el correcto:

Funciones DAX involucradas