VAR

Cálculo de totales acumulados

admin — Mon, 03 Dec 2018 19:19:03 +0000

Cálculo de totales acumulados admin Lun, 03/12/2018 - 20:19

Un escenario frecuente es aquel en el que queremos calcular el total acumulado, incluyendo todos los datos hasta una cierta fecha y no solo los implicados en el contexto de filtro actual. Por ejemplo, si suponemos la existencia de una tabla de ventas Sales que contiene una columna Amount con la cifra de ventas, podríamos definir una medida que calculase la suma de esta columna con la siguiente expresión DAX:

Sales = SUM(Sales[Amount])

Lógicamente, esta medida se va a adaptar al contexto de filtro, por lo que si la llevamos a una matriz en la que se esté desagregando las ventas por año:

...vemos que, para cada año, la cifra de ventas mostrada incluye solo las ventas de dicho año.

Lo que querríamos sería que, en cada evaluación de la medida, el período temporal considerado comenzase el primer día para que el hubo ventas (supongamos que el 1 de enero de 2015) y se extendiese hasta la última fecha del "período actual". Por ejemplo, en la cifra correspondiente al año 2018 el período actual es el correspondiente a los 365 días de dicho año. Pues bien, para el cálculo del acumulado para dicho año querríamos que se considerase el período comprendido entre el 1 de enero de 2015 y el 31 de diciembre de 2018. Es decir, escrito en pseudo-código:

Accumulated sales =
CALCULATE(
[Sales],
Período entre la primera fecha disponible y la última fecha del contexto actual
)

El período en cuestión puede calcularse usando la función DATESBETWEEN que devuelve el conjunto de fechas entre dos dadas. Si el calendario está contenido en la tabla Calendar, tendríamos, por lo tanto, que codificar la siguiente medida:

Accumulated sales =
CALCULATE(
[Sales],
DATESBETWEEN(
'Calendar'[Date],
Primera fecha disponible,
Última fecha del contexto actual
)
)

Ahora bien, es el cálculo de esas dos fechas lo que resulta más complejo, pues queremos que la primera fecha ("Primera fecha disponible") sea absoluta y haga referencia a la primera fecha disponible en el calendario, mientras que la segunda ("Última fecha del contexto actual") queremos que se adapte al contexto.

Para la obtención de la primera fecha disponible en el calendario deberemos asegurarnos de que no se están aplicando filtros al mismo, para lo que podemos usar la función ALL (lo que va a devolver una tabla). Y para la extracción de la primera fecha disponible de dicha tabla no podemos usar la función MIN pues ésta exige una columna como argumento, de forma que tendremos que usar la función FIRSTDATE, que sí acepta una tabla como argumento y devuelve otra tabla (con la fecha más antigua disponible), tabla que podemos pasar a la función CALCULATE como argumento de filtro:

FIRSTDATE(ALL(Sales[Order Date]))

Para el cálculo de la última fecha del contexto actual no tenemos más que utilizar la función MAX pasando como argumento la columna temporal que está desagregando nuestro objeto visual: la columna 'Calendar'[Date]. Es decir, la última fecha del contexto actual vendría dada por:

MAX('Calendar'[Date])

Es decir, la expresión

DATESBETWEEN(
    'Calendar'[Date],
    FIRSTDATE(ALL(Sales[Order Date])),
    MAX('Calendar'[Date])
)

...va a devolver el conjunto de fechas del calendario entre la más antigua disponible y la última implicada en el contexto actual. Podemos escribir, por lo tanto, la medida que devuelve las ventas acumuladas:

Accumulated sales =
CALCULATE(
    [Sales],
    DATESBETWEEN(
        'Calendar'[Date],
        FIRSTDATE(ALL(Sales[Order Date])),
        MAX('Calendar'[Date])
    )
)

Si quisiéramos utilizar variables para hacer más legible el código, podríamos crear dos variables, __firstdate y __lastDate conteniendo las dos fechas implicadas en el código anterior:

Accumulated sales =
VAR __firstDate = FIRSTDATE(ALL(Sales[Order Date]))
VAR __lastDate = MAX('Calendar'[Date])
RETURN
    CALCULATE(
        [Sales],
        DATESBETWEEN(
            'Calendar'[Date],
            __firstDate,
            __lastDate
        )
    )

Ahora, si llevamos la medida anterior a nuestra matriz, comprobamos que se están acumulando las ventas tal y como queríamos:

Y, por supuesto, si mostramos la matriz desagregada por cualquier otro nivel de nuestra jerarquía temporal, por trimestres, por ejemplo, el cálculo de las ventas acumuladas sigue realizándose correctamente:

Funciones DAX involucradas

Dificultad

Intermedia

Cálculo del número de valores previos a cada fecha

admin — Wed, 23 Jun 2021 13:10:10 +0000

Cálculo del número de valores previos a cada fecha admin Mié, 23/06/2021 - 15:10

En este escenario partimos de la siguiente tabla de datos:

Obsérvese que en la tabla las fechas se muestran ordenadas (de más antiguas a más modernas) para hacer más sencilla su interpretación, pero tengamos en mente que podría no ser así.

El objetivo es crear una columna calculada que nos indique, para cada fila, cuántas filas de la misma tabla contienen fechas anteriores a la de la fila siendo considerada (teniendo en cuenta, como se ha comentado, que las filas podrían estar no ordenadas según la fecha).

Como queremos añadir una columna calculada, se va a crear por defecto un contexto de fila para cada una de las filas evaluadas. Es decir, para la primera fila (la correspondiente al campo Id 1) se creará un contexto de fila en el que podremos acceder a los valores de sus campos, Id y Date. A partir del valor del campo Date querríamos filtrar la tabla de forma que solo se considerasen las filas con fechas anteriores y contar el número de filas resultantes.

En pseudo código sería algo así:

Number of Previous values =
COUNTROWS(
FILTER(
data,
data[Date] < fecha-de-la-fila-actual
)
)

Se ha utilizado la etiqueta fecha-de-la-fila-actual para hacer referencia al valor del campo Date de la fila siendo considerada.

La función FILTER, siendo un iterador, va a crear un nuevo contexto de fila en el que evaluar la condición para cada fila de la tabla data:

data[Date] < fecha-de-la-fila-actual

Lógicamente, el siguiente código no funcionaría:

Number of Previous values =
COUNTROWS(
FILTER(
data,
data[Date] < data[Date])
)
)

...pues dentro del contexto de fila creado por FILTER, el valor de data[Date] es el valor del campo Date de la fila que FILTER esté iterando. Lo que querríamos es que el valor de fecha-de-la-fila-actual fuese el definido en el contexto de fila "anterior", el creado por la columna calculada previo a la ejecución de la función FILTER.

Para ello tenemos dos soluciones:

La primera -la única existente hasta que se introdujeron las variables en DAX en 2015- es recurrir a la función EARLIER. Esta función nos devuelve exactamente lo que queremos: el valor de un campo para un contexto de fila anterior (pudiendo indicarse cuántos contextos de fila hay que retroceder). Por ejemplo:

Number of Previous values =
COUNTROWS(
FILTER(
data,
data[Date] < EARLIER(data[Date], 1)
)
)

...devolvería el resultado que buscábamos:

Vemos que, para la primera fila, la función devuelve un Blank pues no hay filas con fechas anteriores y la función COUNTROWS devuelve este valor para tablas vacías. Podemos forzar que, en este caso, se devuelva un 0 usando la función COALESCE:

Number of Previous values =
COALESCE(
COUNTROWS(
FILTER(
data,
data[Date] < EARLIER(data[Date], 1)
)
),
0
)

En este caso, como el contexto "anterior" es el único contexto previo, también podríamos usar la función EARLIEST que nos devuelve el valor del campo indicado en el último contexto de fila existente:

Number of Previous values =
COALESCE(
COUNTROWS(
FILTER(
data,
data[Date] < EARLIEST(data[Date])
)
),
0
)

El segundo método es, precisamente, haciendo uso de variables, lo que resulta mucho más sencillo y fácilmente interpretable. Concretamente:

Number of Previous values =
VAR __currentDate = data[Date]
RETURN
COUNTROWS(
FILTER(
data,
data[Date] < __currentDate
)
)

En primer lugar creamos una variable (__currentDate) con la palabra reservada VAR. Esta variable se va a crear en el contexto de evaluación existente que, en ese punto del código, es el contexto de fila creado por la columna calculada. Es decir, en este punto, el campo data[Date] toma el valor del campo Date en la fila que se esté evaluando.

Una vez registrado el valor de la fecha se ejecuta el filtrado de la tabla data. Tal y como se ha comentado, la función FILTER crea un nuevo contexto de fila en el que se recorre la tabla en cuestión comparando cada valor del campo Date -evaluado en el contexto de fila de la función FILTER- con el valor registrado en la variable __currentDate (valor que se registró en el contexto de fila de la columna calculada):

Comprobamos que el resultado es el mismo que obtuvimos con la función EARLIER pero más fácil de interpretar.

Una vez más, podríamos usar la función COALESCE para forzar ceros allí donde COUNTROWS devuelva Blanks:

Number of Previous values =
VAR __currentDate = data[Date]
RETURN
COALESCE(
COUNTROWS(
FILTER(
data,
data[Date] < __currentDate
)
),
0
)

Funciones DAX involucradas

Dificultad

Intermedia

Creación de un gráfico mostrando el signo de un valor

admin — Tue, 30 Jun 2020 11:41:33 +0000

Creación de un gráfico mostrando el signo de un valor admin Mar, 30/06/2020 - 13:41

En este escenario partimos de una métrica que queremos calcular para cada valor de una variable categórica. Por ejemplo, el "resultado" por país (con independencia de lo que represente este resultado) incluido en un libro Excel:

Nuestro objetivo es mostrar en Power BI un pequeño gráfico para cada uno de estos valores que muestre el signo del mismo, de forma que si el valor es positivo (o cero) se muestre un cierto gráfico y si es negativo, se muestre otro.

Leemos los datos desde Power BI y creamos una tabla que nos servirá para mostrar el listado de países y sus respectivos resultados:

Las gráficas a mostrar serán los símbolos unicode 128200 y 128201:

Aun cuando los colores que muestran no están especialmente bien escogidos (el rojo cuando la gráfica sube y el azul cuando baja) servirán para nuestros propósitos.

Para ver estos símbolos en pantalla podemos crear una sencilla medida DAX que devuelva el símbolo en cuestión:

up = UNICHAR(128200)

Y llevar esta medida a, por ejemplo, una tarjeta:

En todo caso, lo que nos interesa es crear una medida que, a partir de un cierto valor -como el resultado de cada país-, devuelva un símbolo u otro en función del signo de dicho valor.

Como -en este sencillo caso, solo tenemos dos opciones (que el valor sea mayor o igual a cero, o que sea menor que cero), bastaría usar la función IF para evaluar el valor en cuestión y devolver el símbolo adecuado:

Trend = IF(
SUM(data[Result]) >= 0,
UNICHAR(128200),
UNICHAR(128201)
)

Es decir, calculamos la suma del campo "Result" (hay que aplicar una función de agregación al campo necesariamente) y, si es mayor o igual a cero, devolvemos el símbolo unicode 128200. Y si no, el 128201. Si llevamos esta medida a nuestra tabla vemos el resultado:

En un escenario con más de dos opciones tendríamos que usar IFs anidados o, mejor, la función SWITCH, que también podemos usar aquí:

Trend =
VAR results = SUM(data[Result])
RETURN
SWITCH(
TRUE(),
results >= 0, UNICHAR(128200),
results < 0, UNICHAR(128201)
)

En la expresión anterior se ha calculado previamente la suma del campo Result para no tener que ejecutarla posteriormente más de una vez, y devolvemos el resultado de la primera condición que se cumpla: si results (suma del campo Result) es mayor o igual a cero, devolvemos el primer símbolo unicode, y si es negativo el segundo. También podríamos devolver un valor por defecto en el caso de que ninguna de las condiciones se cumpliese. Gráficamente el resultado es, en todo caso, el mismo que teníamos antes:

Funciones DAX involucradas

Completado de una tabla sustituyendo valores inexistentes por ceros

admin — Wed, 30 Oct 2019 09:06:37 +0000

Completado de una tabla sustituyendo valores inexistentes por ceros admin Mié, 30/10/2019 - 10:06

Un caso con el que nos encontramos con cierta frecuencia es aquel en el que tenemos datos tabulares pero no disponemos de valores para todas las combinaciones de filas y columnas, y querríamos tener al menos ceros que nos permitan operar con la tabla completa.

Para ver cómo podemos resolver este problema vamos a partir de la siguiente tabla de datos:

Como vemos, se trata de una tabla en la que se muestran las ventas de tres posibles productos a lo largo de los cuatro trimestres del año, tabla en la que muchas de las combinaciones de trimestres y productos no existen.

Si, tras leer esta tabla con Power BI, llevamos los datos a una matriz, el resultado es el siguiente:

...con blanks en todas aquellas intersecciones de filas y columnas para las que no hay datos en nuestra tabla original.

Pues bien, para crear una tabla a partir de la leída que contenga valores en todas las combinaciones de filas y columnas vamos a comenzar identificando los posibles valores en filas y en columnas -lo que podemos conseguir usando la función VALUES-, y calculando el producto cartesiano de ambos conjuntos con CROSSJOIN:

Tabla =
   CROSSJOIN(
       VALUES(Data[Trimestre]);
       VALUES(Data[Producto])
   )

El resultado se muestra en la siguiente imagen:

A esta tabla le faltaría la columna de "Ventas" para incluir todos los datos que necesitamos. La añadimos con la función ADDCOLUMNS:

Tabla =
ADDCOLUMNS(
CROSSJOIN(
VALUES(Data[Trimestre]);
VALUES(Data[Producto])
);
"Ventas"; 0
)

Ahora ya tenemos la tabla con valores nulos:

Si llevamos esta tabla a una matriz confirmamos que el aspecto es el deseado:

Ahora necesitamos "sumar" los valores de ambas tablas, la original y la que acabamos de crear. Para ello vamos a recurrir a unirlas (verticalmente) con la función UNION:

Tabla =
VAR
tabla1 = ADDCOLUMNS(
CROSSJOIN(
VALUES(Data[Trimestre]);
VALUES(Data[Producto])
);
"Ventas"; 0
)
VAR
tabla2 = Data
RETURN
UNION(
tabla1;
tabla2
)

El resultado es el siguiente:

Como nuestro objetivo es tener una tabla con una única entrada para cada combinación de filas y columnas, la agregamos según estos criterios. El problema con el que nos encontramos aquí es que la función SUMMARIZE, por ejemplo, exige una tabla de base, no una tabla calculada. De forma que vamos a crear una nueva tabla calculada a partir de la anterior:

Tabla completa =
SUMMARIZE(
Tabla;
Tabla[Trimestre];
Tabla[Producto];
"Ventas"; SUM(Tabla[Ventas])
)

El resultado es el esperado:

Ahora ya podemos llevar esta tabla a una matriz y comprobar que incluye todos los valores:

Funciones DAX involucradas

Obtención de los datos de ventas relativos a los 10 productos con mayores ventas

admin — Sun, 28 Jul 2019 10:17:30 +0000

Obtención de los datos de ventas relativos a los 10 productos con mayores ventas admin Dom, 28/07/2019 - 12:17

En este escenario partimos de una tabla de ventas ("Sales") y otra con información sobre los productos ("Products"). En la primera tenemos un campo que indica el producto vendido y otro ("Amount") con la cifra de venta. En la tabla de productos tenemos un campo ("Product name") con el nombre del producto. Obviamente, ambas tablas están relacionadas a través de un campo que contiene el identificador de cada producto.

El objetivo es la creación de una tabla que contenga toda la información de ventas para los 10 productos con mayores ventas (es decir, queremos un subconjunto de la tabla de ventas Sales que contenga información solo de los 10 productos más vendidos). Este escenario es semejante al de Obtención de los 10 clientes que más compras acumulan, salvo por el hecho de que, aquí, no queremos un simple listado de productos con sus cifras de ventas, sino toda la información de ventas relativa a dichos productos.

El plan es sencillo: Generamos una tabla de ventas totales por cada producto, seleccionamos los 10 con mayores cifras y utilizamos esta información para filtrar la tabla original de ventas de forma que solo incluya datos para dichos productos.

Comencemos con la primera de las tablas: la agregación de ventas por producto. Para ello recurrimos a la función SUMMARIZE, especificando como campo de agregación Products[Product name] y como columna a crear la resultante de aplicar la función SUM al campo Sales[Amount]:

10 productos más vendidos =
VAR
VentasPorProducto =
SUMMARIZE(
Sales;
Products[Product name];
"Sales"; SUM(Sales[Amount])
)
RETURN
VentasPorProducto

Como puede verse, se ha llevado la expresión a una variable para poder seguir completando la tabla calculada.

Ahora queremos quedarnos solamente con los 10 productos con mayores ventas, para lo que recurrimos a la función TOPN. Como tabla de partida indicamos la anteriormente obtenida y como expresión, el campo Sales creado:

10 productos más vendidos =
VAR
VentasPorProducto =
SUMMARIZE(
Sales;
Products[Product name];
"Sales"; SUM(Sales[Amount])
)
VAR
ProductosMasVendidos =
TOPN(
10;
VentasPorProducto;
[Sales]
)
RETURN
ProductosMasVendidos

Por último queremos utilizar esta tabla para filtrar la tabla de ventas, Sales. Para ello vamos a utilizar la función NATURALINNERJOIN para crear una combinación natural entre la tabla de ventas y la tabla generada con los productos más vendidos. Al tratarse de una combinación natural interna, solo se mantendrán los registros que compartan los mismos valores en el campo o campos comunes. El campo común es Product Name (en el caso de la tabla Sales, el campo viene dado por su relación con la tabla Products). El código es el siguiente:

...y el resultado es el que podemos ver en la siguiente imagen:

Vemos que se incluyen los campos de ambas tablas. Podríamos seleccionar solo los campos de interés con SELECTCOLUMNS, por ejemplo.

Funciones DAX involucradas

Replicación de cada fila de una tabla un número aleatorio de veces

admin — Sun, 14 Jul 2019 08:56:30 +0000

Replicación de cada fila de una tabla un número aleatorio de veces admin Dom, 14/07/2019 - 10:56

En este escenario partimos de una tabla ("Products") de productos identificados por números enteros consecutivos:

El objetivo es generar otra tabla en la que cada uno de estos registros se haya replicado un número aleatorio de veces. Como puede apreciarse, este escenario es semejante al de Replicación de cada fila de una tabla según una tabla de valores con la salvedad de que ahora no tenemos una tabla que nos indique el número de veces que deberemos replicar cada fila. Pero la idea es semejante: en este caso generaremos la columna conteniendo esos números aleatorios manteniendo el esquema de trabajo que vimos en el escenario mencionado.

Esta columna de números aleatorios la vamos a añadir a las columnas existentes de la tabla Products utilizando el siguiente código:

Products_Extended =
ADDCOLUMNS(
Products;
"RandomValue"; RANDBETWEEN(2; 3)
)

Queremos ahora realizar una combinación cruzada entre la tabla anterior y una segunda tabla con tantas filas como indique el valor de RandomValue que vemos en la imagen anterior (el contenido exacto de dichas filas es irrelevante: lo importante es que contenga el número correcto de filas para que la combinación cruzada "replique" cada fila de la primera tabla el número de veces indicado por el valor generado aleatoriamente). La función a utilizar para realizar la combinación cruzada es GENERATE, y la función para generar la tabla con el número que nos interesa de filas es GENERATESERIES. El código completo es el siguiente:

Products_Extended =
VAR
Random =
ADDCOLUMNS(
Products;
"RandomValue"; RANDBETWEEN(2; 3)
)
RETURN
GENERATE(
Random;
GENERATESERIES(1; [RandomValue])
)

Hemos generado la tabla Random conteniendo los mismos campos que la tabla Products añadiéndole la columna con los valores aleatorios, y se devuelve la combinación cruzada de dicha tabla con la progresión aritmética generada por GENERATESERIES, indicando que deberán generarse [RandomValue] valores (cifra accesible vía contexto de fila para cada fila de la tabla Random para la que la función GENERATE se plantea la combinación cruzada). El resultado es el siguiente:

Obsérvese que la máquina DAX no reconoce el campo RandomValue en el editor de fórmulas, pese a lo cual lo interpreta correctamente. Esto significa que hemos de escribir dicha etiqueta a mano en el código, sin esperar que el sistema "Intellisense" del editor nos lo muestre en la lista de opciones disponibles.

Funciones DAX involucradas

Cálculo del año y mes fiscal correspondientes a cada fecha

admin — Tue, 09 Jul 2019 11:01:19 +0000

Cálculo del año y mes fiscal correspondientes a cada fecha admin Mar, 09/07/2019 - 13:01

En este escenario partimos de una tabla calendario en la que se incluyen campos para el año y el número de mes:

El objetivo es añadir una columna con el año fiscal y otra con el mes fiscal. Para esto vamos a suponer que el mes en el que termina el año fiscal es marzo (tercer mes del año), lo que podremos modificar en cada bloque de código fácilmente.

Para el cálculo del año fiscal vamos a comparar el mes incluido en cada fila con el mes en el que termina el año fiscal: si es superior, sumaremos 1 al valor del año:

FY =
VAR
UltimoMes = 3
RETURN
'Calendar'[Año] +
IF(
MONTH('Calendar'[Date]) > UltimoMes;
1;
0
)

En el código anterior definimos la variable "UltimoMes" con el valor correspondiente al último mes del año fiscal (3) usando la función VAR, y devolvemos el valor del campo Año sumándole 1 o no en función de que el mes de la fecha sea o no superior al último mes del año fiscal. Para esto extraemos el mes de la fecha con la función MONTH y realizamos la comparación con IF. En la imagen anterior se muestran fechas de marzo y abril para ver el salto de un período al otro.

Un par de notas interesantes: Los nombres de las variables no pueden contener espacios, guiones, vocales acentuadas... de ahí el nombre de "UltimoMes". Y observa que es posible incrustar una función (IF, en este caso) donde se espera un valor númerico (siempre que la función devuelva un valor adecuado).

Para añadir el mes fiscal, podemos restar al mes de la fecha (que extraeremos con la función MONTH) el último mes del año fiscal. Esto devolverá un número positivo para los meses posteriores a éste (abril = 1, mayo = 2...), pero un número negativo o cero para los anteriores (enero = -2, febrero = -1 y marzo = 0). Para solucionar esto podemos simplemente calcular el módulo de la resta y 12 usando la función MOD y sumando 1 al resultado (el módulo devolverá cero para marzo, por ejemplo):

FM =
VAR
UltimoMes = 3
RETURN
MOD(MONTH('Calendar'[Date]) - UltimoMes; 12) + 1

Funciones DAX involucradas

VAR

MONTH

MOD

Cálculo del número de días entre compras

admin — Tue, 02 Jul 2019 14:23:33 +0000

Cálculo del número de días entre compras admin Mar, 02/07/2019 - 16:23

Partimos de un listado de ventas (Sales) en el que se indica -por ejemplo- el identificador de cliente y las fechas de las compras:

El objetivo es añadir a esta tabla una columna que indique el número de días transcurridos desde la compra anterior (anterior en el tiempo, pues nada nos asegura que el orden de los datos en la tabla original sea cronológico, y ya sabemos que Power BI tampoco asegura el orden de las filas).

La resolución de este escenario no es sencilla. Aun cuando podría resolverse en una única expresión, se plantea a continuación su resolución paso a paso. Las fases involucradas son las siguientes:

Es necesario obtener, para cada fecha de compra del cliente X, la fecha de la anterior compra.
La anterior fecha de compra es la mayor fecha de todas las compras del cliente X (exceptuando la compra que estemos analizando, por supuesto).
Podemos obtener todas las compras anteriores del cliente X realizando una combinación cruzada de la tabla consigo misma tomando como campo común el correspondiente al identificador del cliente y considerando en la tabla de la derecha (véase la documentación de la función GENERATE) solo las fechas anteriores a la de la fecha de compra siendo considerada en la tabla izquierda. Así, por ejemplo, para la compra que aparece en la tercera línea de la imagen anterior (correspondiente al cliente 1, con fecha de 21 de enero de 2019), una combinación cruzada con la misma tabla en las condiciones mencionadas devolvería una fila para la combinación de la fila 3 y la fila 1 (mismo cliente y fecha anterior) y otra para la combinación de la fila 3 y la fila 2 (de nuevo, mismo cliente y fecha anterior).

Por último, una vez obtenida la tabla mencionada en el punto 1, bastaría calcular la diferencia entre cada fecha de compra y la fecha de la última compra.

Vamos punto por punto.

En primer lugar queremos obtener, para cada fila (es decir, para cada compra), el conjunto de compras anteriores del mismo cliente. Esto, como se ha comentado, puede lograrse con una combinación cruzada que nos permita especificar las condiciones de la combinación, es decir, con la función GENERATE. Como esta función requiere que las tablas involucradas en la combinación tengan campos con nombres diferentes, vamos modificar los nombres de los campos de la segunda copia con la función SELECTCOLUMNS, añadiendo un símbolo "_" al final de los nombres:

SelfJoin =
GENERATE(
Sales;
FILTER(
SELECTCOLUMNS(
Sales;
"Customer_"; Sales[Customer];
"Purchase Date_"; Sales[Purchase Date]
);
[Purchase Date_] < Sales[Purchase Date] && Sales[Customer] = [Customer_]
)
)

Tal y como se ve, estamos obteniendo la combinación cruzada imponiendo la condición de que el identificador de cliente sea el mismo, y que las fechas de la columna de la derecha sean inferiores a la fecha considerada en cada una de las filas de la izquierda (para simplificar, estamos suponiendo que un mismo cliente no va a realizar dos compras el mismo día).

Obsérvese que no aparecen los registros de la primera tabla para los que no hay registros en la segunda que cumplan las condiciones impuestas (es decir, en la tabla que acabamos de crear, solo se incluyen fechas de compra para las que hay alguna compra anterior).

Obtener, a partir de aquí, la fecha anterior a cada compra es fácil: basta con agrupar (con la función GROUPBY) por cliente y fecha de compra (campos Customer y Purchase Date) y seleccionar el valor máximo (de cada grupo) del campo Purchase Date_:

LastPurchases =
GROUPBY(
SelfJoin;
SelfJoin[Customer];
SelfJoin[Purchase Date];
"Last Purchase"; MAXX(
CURRENTGROUP();
SelfJoin[Purchase Date_]
)
)

Ahora viene un proceso un tanto complicado: como en la tabla solo se incluyen fechas de compra para las que existe una compra anterior, para que en el resultado final aparezcan todas las fechas originales tendríamos que realizar una combinación externa izquierda entre la tabla de fechas original y la nueva. Para esto tendríamos que usar la función NATURALLEFTOUTERJOIN, pero esta función exige que las tablas a combinar tengan la misma ascendencia (procedan de la misma fuente), lo que no se cumple en nuestro caso. Tal y como se explica en la documentación de esta función, es posible resolver este problema añadiendo una cadena de texto vacía al final de los nombres:

Purchase and Last Purchase =
NATURALLEFTOUTERJOIN(
SELECTCOLUMNS(
Sales;
"Customer"; Sales[Customer] & "";
"Purchase Date"; Sales[Purchase Date] & ""
);
SELECTCOLUMNS(
LastPurchases;
"Customer"; LastPurchases[SelfJoin_Customer] & "";
"Purchase Date"; LastPurchases[SelfJoin_Purchase Date] & "";
"Last Purchase"; LastPurchases[Last Purchase]
)
)

Por último, para calcular el número de días desde la última compra basta con añadir una nueva columna que devuelva la diferencia (solo si existe una última compra):

Days since last purchase =
ADDCOLUMNS(
'Purchase and Last Purchase';
"# days";
VAR
NumberOfDays =
'Purchase and Last Purchase'[Purchase Date] -
'Purchase and Last Purchase'[Last Purchase]
RETURN
IF(
ISBLANK('Purchase and Last Purchase'[Last Purchase]);
BLANK();
NumberOfDays
)
)

Para devolver la diferencia de días comentada utilizamos la función IF para confirmar si el valor del campo correspondiente a la última compra es un BLANK o no, para lo que utilizamos la función ISBLANK.

Funciones DAX involucradas

Dificultad

Alta

Nombre del producto más vendido

admin — Tue, 15 Jan 2019 14:14:28 +0000

Nombre del producto más vendido admin Mar, 15/01/2019 - 15:14

Calcular el importe total de ventas para el producto más vendido es relativamente fácil. Si el campo que contiene los nombres de los productos es 'Product'[ProductName] y la medida [Total sales] suma el campo correspondiente al importe de ventas, bastaría con crear la siguiente medida:

max_sales = MAXX(VALUES('Product'[ProductName]); [Total sales])

Básicamente estamos extrayendo los nombres de los productos con la función VALUES, calculando las ventas totales para cada uno de ellos y quedándonos con el mayor valor utilizando la función MAXX:

Sin embargo, extraer el nombre del producto correspondiente a dicha cifra no es tan sencillo. Una estrategia -una vez que sabemos cuál es su cifra de ventas- sería recorrer la lista de nombres de productos, calcular su cifra de ventas, compararla con el valor máximo ya conocido y devolver el nombre si la cifra calculada coincide. En pseudo-código, sería algo así:

max_sales = valor de ventas para el producto más vendido

Para cada nombre de producto:

sales = valor de ventas

si sales = max_sales:

return nombre de producto

Una forma de devolver solo el nombre de producto de interés es recorrer el listado de nombres de producto, comparar su cifra de ventas con la cifra máxima ya calculada y devolviendo un valor no vacío si coinciden y un BLANK() si no coinciden, y usar a continuación la función iteractiva FIRSTNONBLANK que extrae el nombre del producto correspondiente al primer (y único en este ejemplo) valor no vacío. En pseudo-código sería:

max_sales = valor de ventas para el producto más vendido

return

FIRSTNONBLANK(

Para cada nombre de producto

sales = valor de ventas

si sales = max_sales:

return cualquier valor no vacío

else:

return BLANK()

)

Es decir, podemos verlo como si estuviésemos generando una tabla temporal de una única columna en la que todos los valores serían blank salvo el correspondiente al producto para el que se cumpliese la condición sales = max_sales (es decir, al producto más vendido). El código anterior en DAX quedaría de la siguiente forma:

Max sales product =

VAR

max_sales = MAXX(VALUES('Product'[ProductName]); [Total sales])

RETURN

FIRSTNONBLANK(

'Product'[ProductName];

IF(

[Total sales] = max_sales ;

BLANK()

)

Comenzamos calculando el valor máximo de ventas (max_sales) y devolviendo el nombre del producto correspondiente al primer (y único) valor no vacío de una imaginaria tabla intermedia, tabla que creamos a partir de la columna conteniendo los nombres de los productos en la que "sustituímos" el nombre del producto más vendido por un 1 (podría ser cualquier otro valor) y el resto de nombres de productos por un blank utilizando la función IF:

Para confirmar que el resultado es correcto podemos crear una visualización con la lista de productos y sus ventas totales, y ordenar dicha tabla según la cifra de ventas:

Como la "tabla temporal" solo contiene un único valor no vacío, también podríamos haber utilizado la función LASTNONBLANK:

Max sales product =

VAR

max_sales = MAXX(VALUES('Product'[ProductName]); [Total sales])

RETURN

LASTNONBLANK(

'Product'[ProductName];

IF(

[Total sales] = max_sales ;

BLANK()

)

Funciones DAX involucradas

Suma de los valores máximos de cada categoría

admin — Tue, 08 Jan 2019 18:19:22 +0000

Suma de los valores máximos de cada categoría admin Mar, 08/01/2019 - 19:19

En este escenario partimos de una tabla de hechos ("Data") en la que cada registro tiene asignado una categoría:

El objetivo es calcular el valor máximo de cada categoría (7 para la categoría A, 3 para B y 8 para C) y sumarlos (18 en este caso).

La resolución de este escenario incluye dos pasos:

1. En el primero deberemos calcular el valor máximo de cada categoría para llegar a una tabla intermedia semejante a la siguiente:

2. En el segundo deberemos recorrer la tabla intermedia generada sumando los valores encontrados.

1er paso

Para crear esta tabla intermedia podemos recurrir tanto a la función SUMMARIZE como a SUMMARIZECOLUMNS o GROUPBY. Veamos los tres casos:

SUMMARIZE

El código sería el siguiente:

Max value per category summarize =

SUMMARIZE(

Data;

Data[Category];

"Max value"; MAX(Data[Value])

)

Básicamente estaríamos agregando el campo Category de la tabla Data para crear el campo "Max value" calculando el valor máximo del campo Data[Value] con la función MAX una vez filtrado:

SUMMARIZECOLUMNS

En este segundo caso el código sería el siguiente:

Max value per category summarizecolumns =

SUMMARIZECOLUMNS(

Data[Category];

"Max value";

MAX(Data[Value])

)

Estamos agregando el campo Data[Category] y creando el nuevo campo "Max value" calculando el valor máximo del campo Data[Value] una vez filtrado, también con la función MAX.

GROUPBY

Por último, utilizando la función GROUPBY el código quedaría de la siguiente forma:

Max value per category groupby =

GROUPBY(

Data;

Data[Category];

"Max value"; MAXX(CURRENTGROUP(); Data[Value])

)

En este caso estamos agrupando la tabla Data según la columna Data[Category] y generando la columna "Max value" utilizando la función iterativa MAXX.

2º paso

Una vez conseguida la tabla anterior usando cualquiera de los tres métodos (supongamos que usando la función GROUPBY), tendremos que volver a agregar la tabla sumando los valores de la columna "Max value". En este paso, al contrario que en el paso anterior, no todas las funciones mencionadas servirían. Veámoslas una a una:

SUMMARIZE

El código para esta primera función sería el siguiente:

Sum of max value per category =
SUMMARIZE(
'Max value per category groupby';
"Max"; SUM('Max value per category groupby'[Max value])
)

Es decir, estaríamos agregando la tabla intermedia creada, Max value per category groupby, sin especificar el campo de agregación (pues no queremos más que la suma) y el nuevo campo a crear, Max, como la suma de los valores. El resultado sería el mostrado en la siguiente imagen:

Al no haber especificado el campo de agregación, DAX agrega todos los valores numéricos.

Obsérvese, en todo caso, que con esta función, SUMMARIZE, no sería posible crear la tabla intermedia y realizar la agregación en una única expresión DAX, pues la función SUMMARIZE devuelve un error ("se espera una tabla de base")

SUMMARIZECOLUMNS

Con esta función, el código sería el siguiente:

Sum of max value per category =
SUMMARIZECOLUMNS(
"Max"; SUM('Max value per category groupby'[Max value])
)

Estamos agregando la tabla intermedia creada, nuevamente sin especificar el campo de agregación, y creando el campo Max como la suma del campo Max value de la tabla intermedia. El resultado es el siguiente:

Al igual que ocurre con SUMMARIZE, el intento de aplicar la función SUMMARIZECOLUMNS a una tabla intermedia creada en la misma expresión DAX devolvería un error.

GROUPBY

En este último caso, el código sería el siguiente:

Sum of max value per category =
VAR Max_value_per_category =
GROUPBY(
Data;
Data[Category];
"Max value"; MAXX(CURRENTGROUP(); Data[Value])
)
RETURN
GROUPBY(
Max_value_per_category;
"Sum"; SUMX(CURRENTGROUP(); [Max value])
)

Estaríamos simplemente agregando la tabla intermedia generando como resultado la suma de los valores Max value de forma iterativa. El resultado es el siguiente:

En este tercer caso, sí es posible crear la tabla intermedia en la misma expresión DAX, lo que hace de esta función la más adecuada para este escenario.

Funciones DAX involucradas