CALCULATETABLE

Cálculo de las ventas totales del país al que pertenece cada ciudad

admin — Sat, 06 Jul 2019 11:19:16 +0000

Cálculo de las ventas totales del país al que pertenece cada ciudad admin Sáb, 06/07/2019 - 13:19

En este escenario partimos de una lista de localizaciones ("Geography") en la que se incluye el nombre de la ciudad y el país al que pertenece (entre otros datos):

...y una tabla de ventas ("Movements") en la que se incluye la fecha de venta, la ciudad a la que está asociada y el importe de venta:

Ambas tablas están relacionadas por el campo Geography Id:

El objetivo es añadir una columna calculada a la tabla de localizaciones en la que se muestren las ventas totales del país al que corresponde el registro.

Al crear la columna calculada se va a recorrer la tabla de localizaciones creándose el contexto de fila correspondiente. Podemos acceder al valor del campo Country usando la función EARLIER, de forma que podríamos seleccionar -para cada fila recorrida- el subconjunto de la tabla de localizaciones que incluye ciudades del país en cuestión. Es decir:

FILTER(
Geography;
Geography[Country] = EARLIER(Geography[Country])
)

...devolvería este subconjunto. A su vez, este subconjunto de ciudades nos permitiría filtrar la tabla de ventas mediante la función CALCULATETABLE, agregando como filtro el subconjunto anterior:

CALCULATETABLE(
   Movements;
   FILTER(
       Geography;
       Geography[Country] = EARLIER(Geography[Country])
   )
);

Por último, no quedaría más que recorrer esta tabla (subconjunto de la tabla de ventas) sumando el campo Sales:

Ventas del país =
SUMX(
CALCULATETABLE(
Movements;
FILTER(
Geography;
Geography[Country] = EARLIER(Geography[Country])
)
);
Movements[Sales]
)

El resultado sería el siguiente:

Podemos confirmar que las cifras son las correctas llevando a una visualización tipo tabla la lista de países y el campo Sales de la tabla de ventas:

Funciones DAX involucradas

Listado de solicitudes de soporte atrasadas

admin — Sat, 13 Apr 2019 09:05:02 +0000

Listado de solicitudes de soporte atrasadas admin Sáb, 13/04/2019 - 11:05

En este sencillo escenario partimos de una tabla que registra solicitudes de soporte que, simplemente, contiene un identificador de solicitud, una fecha límite de respuesta y un campo en el que se indica si la solicitud fue ya respondida o no:

El objetivo es identificar qué solicitudes no han sido atendidas cuya fecha límite de asistencia haya vencido. Para esto vamos a crear una tabla calculada en la que implementaremos una función cuyo pseudo-código sería el siguiente:

Filtra la tabla de solicitudes
Incluyendo solo aquellas solicitudes no respondidas
Y cuya fecha límite sea anterior a la fecha de hoy

Para filtrar la tabla de solicitudes podemos usar la función CALCULATETABLE, que nos permite modificar el contexto de cálculo añadiendo los filtros que necesitemos, filtros que, además, se aplican de modo simultáneo (es decir, unidos por un operador lógico AND que obliga a que se cumplan todos ellos). Para imponer el filtro que muestre solo las solicitudes no respondidas, aprovechando que el campo Respondida es booleano e incluye el valor TRUE cuando la solicitud ha sido respondida, basta negar dicho campo con la función NOT. Por último, para mostrar solo las solicitudes cuya fecha límite sea anterior a la fecha de hoy utilizaremos la función TODAY que devuelve la fecha actual.

El código quedaría de la siguiente forma (supongamos que la fecha devuelta por la función TODAY es 13 de abril de 2019):

Solicitudes atrasadas =
CALCULATETABLE(
Solicitudes;
NOT(Solicitudes[Respondida]);
Solicitudes[Fecha límite] < TODAY()
)

Funciones DAX involucradas

CALCULATETABLE

NOT

TODAY

Número de ventas por día de la semana según el día de venta y el día de envío

admin — Sun, 06 Jan 2019 16:17:08 +0000

Número de ventas por día de la semana según el día de venta y el día de envío admin Dom, 06/01/2019 - 17:17

En este escenario partimos de una tabla de ventas, Sales, en la que se incluye un campo con la referencia del día de la orden de venta, OrderDateKey, y otro con la referencia del día del envío del producto, ShipDateKey. Hay, por supuesto, una tabla conteniendo el calendario, Calendar en la que se especifica el día de la semana de cada fecha en el campo DayName. Entre ambas tablas, Sales y Calendar, existe una relación de tipo muchos a uno entre los campos OrderDateKey y DateKey, respectivamente.

El objetivo es averiguar cuántas ventas se realizan por día de la semana y cuántos envíos de productos se realizan por día de la semana.

Podríamos pensar que para esto bastaría generar sendas tablas con visualizaciones llevando a éstas el campo 'Calendar'[DayName] (a ambas tablas) y los campos OrderDateKey y ShipDateKey de la tabla Sales (un campo a cada tabla), asegurándonos de que se aplique un recuento sobre estos últimos dos campos. El resultado sería el siguiente:

Aun cuando los días no se muestran en orden, comprobamos que ambas visualizaciones muestran exactamente la misma información, lo que no es coherente con los datos de los que disponemos. El motivo de este aparente error es que ambas visualizaciones son generadas utilizando la misma relación entre las dos tablas -la relación que une los ya mencionados campos Sales[OrderDateKey] y Calendar[DateKey]- por lo que, con independencia del campo del que partamos en la tabla Sales (OrderDateKey o ShipDateKey), el registro de destino en la tabla Calendar es siempre el mismo y, consecuentemente, el día de la semana asignado es también el mismo.

Lo que necesitamos es crear estas tablas utilizando dos relaciones distintas: una -la que utilizaremos para generar la tabla con el número de ventas según el día en que ésta se realiza- será la relación que ya existe entre los campos Sales[OrderDate] y Calendar[DateKey]. La segunda -a usar en la tabla que incluirá información relativa al número de envíos por día de la semana- deberá unir los campos Sales[ShipDateKey] y Calendar[DateKey].

Creamos, por lo tanto, esta segunda relación entre las tablas Sales y Calendar. Como solo puede existir una relación activa entre dos tablas, esta segunda relación se mostrará desactivada, aunque podrá ser utilizada en las funciones DAX que la requieran:

Vamos a generar a continuación las dos tablas utilizando la función SUMMARIZE, Esta función nos permitirá resumir el campo de fecha que nos interese de la tabla de ventas (realizando un recuento del mismo) para cada uno de los valores que tome el campo remoto Calendar[DayName]. Así, para la tabla que deberá mostrar el número de órdenes de venta por día de la semana, la función a utilizar sería:

Tabla intermedia = SUMMARIZE(

Sales;

'Calendar'[DayName];

"Number of orders"; COUNT(Sales[OrderDateKey])

);

Es decir, estaríamos generando una tabla a partir de la tabla Sales, agrupando los resultados por los valores del campo remoto 'Calendar'[DayName] y totalizando el campo Sales[OrderDateKey] contando sus registros y dando a este campo de agregación, en este ejemplo, el nombre Number of orders.

Para la primera de las tablas a generar, esto ya sería suficiente. Pero vamos a generalizar el resultado para poder aplicar el mismo código a la segunda tabla a generar sin tener que realizar grandes modificaciones. Para esto tendríamos que añadir al código generado la opción de especificar la relación a usar, para lo que utilizaremos la función USERELATIONSHIP. Esta función se aplica como un filtro a una tabla, por lo que podemos recurrir a la función CALCULATETABLE para modificar la tabla intermedia con el filtro en cuestión. El código sería algo como:

Tabla final = CALCULATETABLE(

Tabla intermedia;

USERELATIONSHIP(relación-a-usar)

)

El código para generar la primera tabla (recordemos que es la tabla que muestra el número de órdenes de venta por día de la semana) sería, por lo tanto:

Number of order dates per day of week =

CALCULATETABLE(

SUMMARIZE(

Sales;

'Calendar'[DayName];

"Number of order dates"; COUNT(Sales[OrderDateKey])

);

USERELATIONSHIP(Sales[OrderDateKey]; 'Calendar'[DateKey])

)

La relación a usar es la activa, por lo que, tal y como se ha dicho, esta parte es redundante. Pero nos permite generar la segunda tabla con una mínima modificación del código:

Number of ship dates per day of week =

CALCULATETABLE(

SUMMARIZE(

Sales;

'Calendar'[DayName];

"Number of ship dates"; COUNT(Sales[ShipDateKey])

);

USERELATIONSHIP(Sales[ShipDateKey]; 'Calendar'[DateKey])

)

En esta segunda versión, la única diferencia es el origen de la relación a usar: Sales[ShipDateKey] en lugar del campo por defecto Sales[OrderDateKey].

Las tablas generadas podrían ser usada en nuevos cálculos pero, en este ejemplo, vamos a crear tablas calculadas. Para la primera el resultado sería el siguiente:

Y para la segunda sería el siguiente:

Comprobamos ahora cómo ambas tablas muestran información diferente, tal y como era de esperar.

Funciones DAX involucradas