SUMMARIZE

Completado de una tabla sustituyendo valores inexistentes por ceros

admin — Wed, 30 Oct 2019 09:06:37 +0000

Completado de una tabla sustituyendo valores inexistentes por ceros admin Mié, 30/10/2019 - 10:06

Un caso con el que nos encontramos con cierta frecuencia es aquel en el que tenemos datos tabulares pero no disponemos de valores para todas las combinaciones de filas y columnas, y querríamos tener al menos ceros que nos permitan operar con la tabla completa.

Para ver cómo podemos resolver este problema vamos a partir de la siguiente tabla de datos:

Como vemos, se trata de una tabla en la que se muestran las ventas de tres posibles productos a lo largo de los cuatro trimestres del año, tabla en la que muchas de las combinaciones de trimestres y productos no existen.

Si, tras leer esta tabla con Power BI, llevamos los datos a una matriz, el resultado es el siguiente:

...con blanks en todas aquellas intersecciones de filas y columnas para las que no hay datos en nuestra tabla original.

Pues bien, para crear una tabla a partir de la leída que contenga valores en todas las combinaciones de filas y columnas vamos a comenzar identificando los posibles valores en filas y en columnas -lo que podemos conseguir usando la función VALUES-, y calculando el producto cartesiano de ambos conjuntos con CROSSJOIN:

Tabla =
   CROSSJOIN(
       VALUES(Data[Trimestre]);
       VALUES(Data[Producto])
   )

El resultado se muestra en la siguiente imagen:

A esta tabla le faltaría la columna de "Ventas" para incluir todos los datos que necesitamos. La añadimos con la función ADDCOLUMNS:

Tabla =
ADDCOLUMNS(
CROSSJOIN(
VALUES(Data[Trimestre]);
VALUES(Data[Producto])
);
"Ventas"; 0
)

Ahora ya tenemos la tabla con valores nulos:

Si llevamos esta tabla a una matriz confirmamos que el aspecto es el deseado:

Ahora necesitamos "sumar" los valores de ambas tablas, la original y la que acabamos de crear. Para ello vamos a recurrir a unirlas (verticalmente) con la función UNION:

Tabla =
VAR
tabla1 = ADDCOLUMNS(
CROSSJOIN(
VALUES(Data[Trimestre]);
VALUES(Data[Producto])
);
"Ventas"; 0
)
VAR
tabla2 = Data
RETURN
UNION(
tabla1;
tabla2
)

El resultado es el siguiente:

Como nuestro objetivo es tener una tabla con una única entrada para cada combinación de filas y columnas, la agregamos según estos criterios. El problema con el que nos encontramos aquí es que la función SUMMARIZE, por ejemplo, exige una tabla de base, no una tabla calculada. De forma que vamos a crear una nueva tabla calculada a partir de la anterior:

Tabla completa =
SUMMARIZE(
Tabla;
Tabla[Trimestre];
Tabla[Producto];
"Ventas"; SUM(Tabla[Ventas])
)

El resultado es el esperado:

Ahora ya podemos llevar esta tabla a una matriz y comprobar que incluye todos los valores:

Funciones DAX involucradas

Obtención de los datos de ventas relativos a los 10 productos con mayores ventas

admin — Sun, 28 Jul 2019 10:17:30 +0000

Obtención de los datos de ventas relativos a los 10 productos con mayores ventas admin Dom, 28/07/2019 - 12:17

En este escenario partimos de una tabla de ventas ("Sales") y otra con información sobre los productos ("Products"). En la primera tenemos un campo que indica el producto vendido y otro ("Amount") con la cifra de venta. En la tabla de productos tenemos un campo ("Product name") con el nombre del producto. Obviamente, ambas tablas están relacionadas a través de un campo que contiene el identificador de cada producto.

El objetivo es la creación de una tabla que contenga toda la información de ventas para los 10 productos con mayores ventas (es decir, queremos un subconjunto de la tabla de ventas Sales que contenga información solo de los 10 productos más vendidos). Este escenario es semejante al de Obtención de los 10 clientes que más compras acumulan, salvo por el hecho de que, aquí, no queremos un simple listado de productos con sus cifras de ventas, sino toda la información de ventas relativa a dichos productos.

El plan es sencillo: Generamos una tabla de ventas totales por cada producto, seleccionamos los 10 con mayores cifras y utilizamos esta información para filtrar la tabla original de ventas de forma que solo incluya datos para dichos productos.

Comencemos con la primera de las tablas: la agregación de ventas por producto. Para ello recurrimos a la función SUMMARIZE, especificando como campo de agregación Products[Product name] y como columna a crear la resultante de aplicar la función SUM al campo Sales[Amount]:

10 productos más vendidos =
VAR
VentasPorProducto =
SUMMARIZE(
Sales;
Products[Product name];
"Sales"; SUM(Sales[Amount])
)
RETURN
VentasPorProducto

Como puede verse, se ha llevado la expresión a una variable para poder seguir completando la tabla calculada.

Ahora queremos quedarnos solamente con los 10 productos con mayores ventas, para lo que recurrimos a la función TOPN. Como tabla de partida indicamos la anteriormente obtenida y como expresión, el campo Sales creado:

10 productos más vendidos =
VAR
VentasPorProducto =
SUMMARIZE(
Sales;
Products[Product name];
"Sales"; SUM(Sales[Amount])
)
VAR
ProductosMasVendidos =
TOPN(
10;
VentasPorProducto;
[Sales]
)
RETURN
ProductosMasVendidos

Por último queremos utilizar esta tabla para filtrar la tabla de ventas, Sales. Para ello vamos a utilizar la función NATURALINNERJOIN para crear una combinación natural entre la tabla de ventas y la tabla generada con los productos más vendidos. Al tratarse de una combinación natural interna, solo se mantendrán los registros que compartan los mismos valores en el campo o campos comunes. El campo común es Product Name (en el caso de la tabla Sales, el campo viene dado por su relación con la tabla Products). El código es el siguiente:

...y el resultado es el que podemos ver en la siguiente imagen:

Vemos que se incluyen los campos de ambas tablas. Podríamos seleccionar solo los campos de interés con SELECTCOLUMNS, por ejemplo.

Funciones DAX involucradas

Agregación de dos tablas con la misma estructura

admin — Wed, 10 Apr 2019 08:58:12 +0000

Agregación de dos tablas con la misma estructura admin Mié, 10/04/2019 - 10:58

Un escenario frecuente y sencillo de resolver es aquel en el que nos encontramos con dos tablas de idéntica estructura que deseamos agregar según algún campo. Veamos cómo sería. Suponemos que ya hemos obtenido los datos y tenemos cargadas en Power BI las dos tablas que, en este caso, contienen información de ventas:

En este escenario queremos obtener el total de ventas por vendedor. Vamos a hacerlo en dos fases:

Unión de las tablas anteriores
Agregación de la tabla completa para mostrar las ventas (campo "Precio final") según el campo que identifica cada vendedor

Para el primer paso vamos a recurrir a la función UNION. Sin embargo, no vamos a unir las tablas directamente pues, como vemos en las imágenes anteriores, a pesar de tener la misma estructura (y, en el editor de consultas, aparecer con las columnas en el mismo orden) cuando se importan a Power BI las columnas no se muestran en el mismo orden (probablemente por un bug en el software que existe desde, al menos, finales de 2017). Es por ello que vamos a aplicar la función UNION a las tablas especificando a mano las columnas que nos interesan y el orden que nos interesa, para lo que recurriremos a la función SELECTCOLUMNS:

Ventas totales =
VAR
Tabla1 = SELECTCOLUMNS(
Ventas1;
"Vendedor"; Ventas1[Id Vendedor];
"PVP"; Ventas1[Precio final]
)
VAR
Tabla2 = SELECTCOLUMNS(
Ventas2;
"Vendedor"; Ventas2[Id Vendedor];
"PVP"; Ventas2[Precio final]
)
RETURN
UNION(Tabla1; Tabla2)

Hemos seleccionado apenas las columnas "Vendedor" y "Precio final" (con el nombre de "PVP") pero podríamos haber seleccionado otras columnas también.

Ahora, para el segundo paso, utilizamos la función SUMMARIZE para agregar la tabla anterior:

Ventas totales por vendedor =
SUMMARIZE(
'Ventas totales';
'Ventas totales'[Vendedor];
"Ventas"; SUM('Ventas totales'[PVP]
)
)

Funciones DAX involucradas

Dificultad

Intermedia

Suma de los valores máximos de cada categoría

admin — Tue, 08 Jan 2019 18:19:22 +0000

Suma de los valores máximos de cada categoría admin Mar, 08/01/2019 - 19:19

En este escenario partimos de una tabla de hechos ("Data") en la que cada registro tiene asignado una categoría:

El objetivo es calcular el valor máximo de cada categoría (7 para la categoría A, 3 para B y 8 para C) y sumarlos (18 en este caso).

La resolución de este escenario incluye dos pasos:

1. En el primero deberemos calcular el valor máximo de cada categoría para llegar a una tabla intermedia semejante a la siguiente:

2. En el segundo deberemos recorrer la tabla intermedia generada sumando los valores encontrados.

1er paso

Para crear esta tabla intermedia podemos recurrir tanto a la función SUMMARIZE como a SUMMARIZECOLUMNS o GROUPBY. Veamos los tres casos:

SUMMARIZE

El código sería el siguiente:

Max value per category summarize =

SUMMARIZE(

Data;

Data[Category];

"Max value"; MAX(Data[Value])

)

Básicamente estaríamos agregando el campo Category de la tabla Data para crear el campo "Max value" calculando el valor máximo del campo Data[Value] con la función MAX una vez filtrado:

SUMMARIZECOLUMNS

En este segundo caso el código sería el siguiente:

Max value per category summarizecolumns =

SUMMARIZECOLUMNS(

Data[Category];

"Max value";

MAX(Data[Value])

)

Estamos agregando el campo Data[Category] y creando el nuevo campo "Max value" calculando el valor máximo del campo Data[Value] una vez filtrado, también con la función MAX.

GROUPBY

Por último, utilizando la función GROUPBY el código quedaría de la siguiente forma:

Max value per category groupby =

GROUPBY(

Data;

Data[Category];

"Max value"; MAXX(CURRENTGROUP(); Data[Value])

)

En este caso estamos agrupando la tabla Data según la columna Data[Category] y generando la columna "Max value" utilizando la función iterativa MAXX.

2º paso

Una vez conseguida la tabla anterior usando cualquiera de los tres métodos (supongamos que usando la función GROUPBY), tendremos que volver a agregar la tabla sumando los valores de la columna "Max value". En este paso, al contrario que en el paso anterior, no todas las funciones mencionadas servirían. Veámoslas una a una:

SUMMARIZE

El código para esta primera función sería el siguiente:

Sum of max value per category =
SUMMARIZE(
'Max value per category groupby';
"Max"; SUM('Max value per category groupby'[Max value])
)

Es decir, estaríamos agregando la tabla intermedia creada, Max value per category groupby, sin especificar el campo de agregación (pues no queremos más que la suma) y el nuevo campo a crear, Max, como la suma de los valores. El resultado sería el mostrado en la siguiente imagen:

Al no haber especificado el campo de agregación, DAX agrega todos los valores numéricos.

Obsérvese, en todo caso, que con esta función, SUMMARIZE, no sería posible crear la tabla intermedia y realizar la agregación en una única expresión DAX, pues la función SUMMARIZE devuelve un error ("se espera una tabla de base")

SUMMARIZECOLUMNS

Con esta función, el código sería el siguiente:

Sum of max value per category =
SUMMARIZECOLUMNS(
"Max"; SUM('Max value per category groupby'[Max value])
)

Estamos agregando la tabla intermedia creada, nuevamente sin especificar el campo de agregación, y creando el campo Max como la suma del campo Max value de la tabla intermedia. El resultado es el siguiente:

Al igual que ocurre con SUMMARIZE, el intento de aplicar la función SUMMARIZECOLUMNS a una tabla intermedia creada en la misma expresión DAX devolvería un error.

GROUPBY

En este último caso, el código sería el siguiente:

Sum of max value per category =
VAR Max_value_per_category =
GROUPBY(
Data;
Data[Category];
"Max value"; MAXX(CURRENTGROUP(); Data[Value])
)
RETURN
GROUPBY(
Max_value_per_category;
"Sum"; SUMX(CURRENTGROUP(); [Max value])
)

Estaríamos simplemente agregando la tabla intermedia generando como resultado la suma de los valores Max value de forma iterativa. El resultado es el siguiente:

En este tercer caso, sí es posible crear la tabla intermedia en la misma expresión DAX, lo que hace de esta función la más adecuada para este escenario.

Funciones DAX involucradas

Número de ventas por día de la semana según el día de venta y el día de envío

admin — Sun, 06 Jan 2019 16:17:08 +0000

Número de ventas por día de la semana según el día de venta y el día de envío admin Dom, 06/01/2019 - 17:17

En este escenario partimos de una tabla de ventas, Sales, en la que se incluye un campo con la referencia del día de la orden de venta, OrderDateKey, y otro con la referencia del día del envío del producto, ShipDateKey. Hay, por supuesto, una tabla conteniendo el calendario, Calendar en la que se especifica el día de la semana de cada fecha en el campo DayName. Entre ambas tablas, Sales y Calendar, existe una relación de tipo muchos a uno entre los campos OrderDateKey y DateKey, respectivamente.

El objetivo es averiguar cuántas ventas se realizan por día de la semana y cuántos envíos de productos se realizan por día de la semana.

Podríamos pensar que para esto bastaría generar sendas tablas con visualizaciones llevando a éstas el campo 'Calendar'[DayName] (a ambas tablas) y los campos OrderDateKey y ShipDateKey de la tabla Sales (un campo a cada tabla), asegurándonos de que se aplique un recuento sobre estos últimos dos campos. El resultado sería el siguiente:

Aun cuando los días no se muestran en orden, comprobamos que ambas visualizaciones muestran exactamente la misma información, lo que no es coherente con los datos de los que disponemos. El motivo de este aparente error es que ambas visualizaciones son generadas utilizando la misma relación entre las dos tablas -la relación que une los ya mencionados campos Sales[OrderDateKey] y Calendar[DateKey]- por lo que, con independencia del campo del que partamos en la tabla Sales (OrderDateKey o ShipDateKey), el registro de destino en la tabla Calendar es siempre el mismo y, consecuentemente, el día de la semana asignado es también el mismo.

Lo que necesitamos es crear estas tablas utilizando dos relaciones distintas: una -la que utilizaremos para generar la tabla con el número de ventas según el día en que ésta se realiza- será la relación que ya existe entre los campos Sales[OrderDate] y Calendar[DateKey]. La segunda -a usar en la tabla que incluirá información relativa al número de envíos por día de la semana- deberá unir los campos Sales[ShipDateKey] y Calendar[DateKey].

Creamos, por lo tanto, esta segunda relación entre las tablas Sales y Calendar. Como solo puede existir una relación activa entre dos tablas, esta segunda relación se mostrará desactivada, aunque podrá ser utilizada en las funciones DAX que la requieran:

Vamos a generar a continuación las dos tablas utilizando la función SUMMARIZE, Esta función nos permitirá resumir el campo de fecha que nos interese de la tabla de ventas (realizando un recuento del mismo) para cada uno de los valores que tome el campo remoto Calendar[DayName]. Así, para la tabla que deberá mostrar el número de órdenes de venta por día de la semana, la función a utilizar sería:

Tabla intermedia = SUMMARIZE(

Sales;

'Calendar'[DayName];

"Number of orders"; COUNT(Sales[OrderDateKey])

);

Es decir, estaríamos generando una tabla a partir de la tabla Sales, agrupando los resultados por los valores del campo remoto 'Calendar'[DayName] y totalizando el campo Sales[OrderDateKey] contando sus registros y dando a este campo de agregación, en este ejemplo, el nombre Number of orders.

Para la primera de las tablas a generar, esto ya sería suficiente. Pero vamos a generalizar el resultado para poder aplicar el mismo código a la segunda tabla a generar sin tener que realizar grandes modificaciones. Para esto tendríamos que añadir al código generado la opción de especificar la relación a usar, para lo que utilizaremos la función USERELATIONSHIP. Esta función se aplica como un filtro a una tabla, por lo que podemos recurrir a la función CALCULATETABLE para modificar la tabla intermedia con el filtro en cuestión. El código sería algo como:

Tabla final = CALCULATETABLE(

Tabla intermedia;

USERELATIONSHIP(relación-a-usar)

)

El código para generar la primera tabla (recordemos que es la tabla que muestra el número de órdenes de venta por día de la semana) sería, por lo tanto:

Number of order dates per day of week =

CALCULATETABLE(

SUMMARIZE(

Sales;

'Calendar'[DayName];

"Number of order dates"; COUNT(Sales[OrderDateKey])

);

USERELATIONSHIP(Sales[OrderDateKey]; 'Calendar'[DateKey])

)

La relación a usar es la activa, por lo que, tal y como se ha dicho, esta parte es redundante. Pero nos permite generar la segunda tabla con una mínima modificación del código:

Number of ship dates per day of week =

CALCULATETABLE(

SUMMARIZE(

Sales;

'Calendar'[DayName];

"Number of ship dates"; COUNT(Sales[ShipDateKey])

);

USERELATIONSHIP(Sales[ShipDateKey]; 'Calendar'[DateKey])

)

En esta segunda versión, la única diferencia es el origen de la relación a usar: Sales[ShipDateKey] en lugar del campo por defecto Sales[OrderDateKey].

Las tablas generadas podrían ser usada en nuevos cálculos pero, en este ejemplo, vamos a crear tablas calculadas. Para la primera el resultado sería el siguiente:

Y para la segunda sería el siguiente:

Comprobamos ahora cómo ambas tablas muestran información diferente, tal y como era de esperar.

Funciones DAX involucradas

Obtención de los 10 clientes que más compras acumulan

admin — Fri, 04 Jan 2019 09:39:44 +0000

Obtención de los 10 clientes que más compras acumulan admin Vie, 04/01/2019 - 10:39

En este escenario partimos de una tabla de ventas (Sales) que contiene, entre otros campos, la clave que identifica cada cliente (CustomerKey) y el monto involucrado en cada compra (SalesAmount). El objetivo es generar una tabla (que puede ser añadida al modelo de datos o tratada como argumento en otras funciones) que incluya los 10 clientes que más compras acumulan. En este ejemplo concreto se creará una tabla calculada con esta información.

El proceso a seguir es:

Obtención de una tabla que resuma las compras por cliente
Ordenación y filtrado de dicha tabla para extraer apenas los 10 mayores

Para la obtención de la tabla recurrimos a la función SUMMARIZE:

VAR SalesByCustomer =

SUMMARIZE(

Sales;

Sales[CustomerKey];

"Total spent"; SUM(Sales[SalesAmount])

)

Estamos resumiendo la tabla Sales, agrupándola por el campo CustomerKey y totalizando, para cada CustomerKey, la suma de las ventas.

A continuación no queda más que extraer los 10 valores de CustomerKey que más ventas acumulan, para lo que recurrimos a la función TOPN:

VAR SummaryTableFiltered =

TOPN(

10;

SalesByCustomer;

[Total spent]

)

Extraemos 10 registros de la tabla creada en el paso anterior, SalesByCustomer, tomando como criterio el campo Total spent. Obsérvese que éste campo ha sido también creado en el paso anterior.

Por último, no queda más que dar un nombre a la tabla que estamos creando (Top 10 customers) y devolver el resultado. El código final es el siguiente:

Top 10 customers =

VAR SalesByCustomer =

SUMMARIZE(

Sales;

Sales[CustomerKey];

"Total spent"; SUM(Sales[SalesAmount])

)

VAR SummaryTableFiltered =

TOPN(

10;

SalesByCustomer;

[Total spent]

)

RETURN SummaryTableFiltered

Funciones DAX involucradas