MONTH

Cálculo del año y mes fiscal correspondientes a cada fecha

admin — Tue, 09 Jul 2019 11:01:19 +0000

Cálculo del año y mes fiscal correspondientes a cada fecha admin Mar, 09/07/2019 - 13:01

En este escenario partimos de una tabla calendario en la que se incluyen campos para el año y el número de mes:

El objetivo es añadir una columna con el año fiscal y otra con el mes fiscal. Para esto vamos a suponer que el mes en el que termina el año fiscal es marzo (tercer mes del año), lo que podremos modificar en cada bloque de código fácilmente.

Para el cálculo del año fiscal vamos a comparar el mes incluido en cada fila con el mes en el que termina el año fiscal: si es superior, sumaremos 1 al valor del año:

FY =
VAR
UltimoMes = 3
RETURN
'Calendar'[Año] +
IF(
MONTH('Calendar'[Date]) > UltimoMes;
1;
0
)

En el código anterior definimos la variable "UltimoMes" con el valor correspondiente al último mes del año fiscal (3) usando la función VAR, y devolvemos el valor del campo Año sumándole 1 o no en función de que el mes de la fecha sea o no superior al último mes del año fiscal. Para esto extraemos el mes de la fecha con la función MONTH y realizamos la comparación con IF. En la imagen anterior se muestran fechas de marzo y abril para ver el salto de un período al otro.

Un par de notas interesantes: Los nombres de las variables no pueden contener espacios, guiones, vocales acentuadas... de ahí el nombre de "UltimoMes". Y observa que es posible incrustar una función (IF, en este caso) donde se espera un valor númerico (siempre que la función devuelva un valor adecuado).

Para añadir el mes fiscal, podemos restar al mes de la fecha (que extraeremos con la función MONTH) el último mes del año fiscal. Esto devolverá un número positivo para los meses posteriores a éste (abril = 1, mayo = 2...), pero un número negativo o cero para los anteriores (enero = -2, febrero = -1 y marzo = 0). Para solucionar esto podemos simplemente calcular el módulo de la resta y 12 usando la función MOD y sumando 1 al resultado (el módulo devolverá cero para marzo, por ejemplo):

FM =
VAR
UltimoMes = 3
RETURN
MOD(MONTH('Calendar'[Date]) - UltimoMes; 12) + 1

Funciones DAX involucradas

VAR

MONTH

MOD

Creación de un calendario

admin — Sun, 07 Jul 2019 16:20:39 +0000

Creación de un calendario admin Dom, 07/07/2019 - 18:20

Una de las preguntas más frecuentes relativas al calendario necesario para utilizar funciones de inteligencia de tiempo es ¿Es mejor crearlo externamente a Power BI? ¿O en el editor de consultas? ¿O tal vez con DAX?

En este escenario vamos a crear un calendario completo en DAX, incluyendo el número y nombre del mes, trimestre, día de la semana, etc.

Para comenzar, creamos la tabla con el calendario básico usando la función CALENDARAUTO. Esta función crea una tabla con una única columna con una secuencia de fechas cubriendo todas las fechas que aparezcan en nuestro conjunto de datos, por defecto desde el 1 de enero del primer año hasta el 31 de diciembre del último año:

Calendar = CALENDARAUTO()

Sin embargo, queremos añadir a esta tabla básica otros campos, para lo que vamos a usar las siguientes funciones DAX (obsérvese en la imagen anterior que el campo creado recibe el nombre de "Date"):

Para crear el año: YEAR
Para crear el número de mes: MONTH
Para crear el número de día: DAY

Estos nuevos campos los vamos a añadir a la tabla básica usando la función ADDCOLUMNS:

Calendar =
ADDCOLUMNS(
CALENDARAUTO();
"Year"; YEAR([Date]);
"Month"; MONTH([Date]);
"Day"; DAY([Date])
)

Los nombres para el mes y el día de la semana podemos crearlos con la función FORMAT, y el número de la semana y el número de día de la semana con las funciones WEEKNUM y WEEKDAY, respectivamente:

Calendar =
ADDCOLUMNS(
CALENDARAUTO();
"Year"; YEAR([Date]);
"Month"; MONTH([Date]);
"Month Name"; FORMAT([Date]; "MMMM");
"Week #"; WEEKNUM([Date]);
"Day"; DAY([Date]);
"Week Day"; WEEKDAY([Date]);
"Day Name"; FORMAT([Date]; "DDDD")
)

Por último, para obtener el número de trimestre podemos recurrir a la fórmula:

CEILING(MONTH([Date])/3;1)

...que calcula el entero más próximo igual o superior al mes dividido entre 3 (con la función CEILING) .

Si quisiéramos también tener el equivalente precedido por una "Q", podemos volver a recurrir a la función FORMAT y al operador & que nos permite concatenar cadenas de texto:

Calendar =
ADDCOLUMNS(
CALENDARAUTO();
"Year"; YEAR([Date]);
"Quarter #"; CEILING(MONTH([Date])/3;1);
"Quarter"; "Q" & FORMAT(CEILING(MONTH([Date])/3;1); "#");
"Month"; MONTH([Date]);
"Month Name"; FORMAT([Date]; "MMMM");
"Week #"; WEEKNUM([Date]);
"Day"; DAY([Date]);
"Week Day"; WEEKDAY([Date]);
"Day Name"; FORMAT([Date]; "DDDD")
)

Funciones DAX involucradas

Dificultad

Baja

Creación de un campo de texto a partir de un campo de fechas

admin — Mon, 07 Jan 2019 20:41:41 +0000

Creación de un campo de texto a partir de un campo de fechas admin Lun, 07/01/2019 - 21:41

En este sencillo escenario vamos a crear un campo con la versión de texto de otro campo de fechas (para convertir, por ejemplo, una fecha del tipo 21 de mayo de 2018 en "20180521", teniendo todos los valores de la nueva columna la misma longitud).

Supongamos que nuestro campo de fechas con formato datetime es Sales[Ship Date]:

Para formar nuestra nueva columna deberemos extraer el año, mes y día (podríamos hacerlo más complejo extrayendo la hora, etc.) con las funciones YEAR, MONTH y DAY. Una primera versión de la expresión para crear la nueva columna podría ser, sencillamente, la concatenación de dichos valores, pero podemos ver que no funcionaría con días o meses menores de 10, pues resultarían cadenas de texto de menos de 8 caracteres (en lugar de usar la función CONCATENATE vamos a usar el operador de concatenación &):

ShipDateKey = YEAR(Sales[Ship Date]) & MONTH(Sales[Ship Date]) & DAY(Sales[Ship Date])

Debemos asegurar que tanto el mes como el día tienen ceros a la izquierda en caso de ser necesario para mantener la longitud de 2 caracteres (el año -en nuestros datos- siempre tiene 4 caracteres de longitud). Para esto podemos utilizar la función FORMAT o añadir un cero a la izquierda del mes y del día (tanto si se necesita como si no) y extraer los dos caracteres de la derecha, alternativa que utilizaremos aquí por motivos pedagógicos. Si el cero no hacía falta, los dos caracteres que extraigamos serán los originales. Si, por el contrario, era necesario, estaremos extrayendo el cero y el valor original. Así, por ejemplo, si hemos extraído los meses 11 y 5, esta operación resultaría en las siguientes cadenas de texto:

"0" & "11" = "011" » "11"

"0" & "5" = "05" » "05"

Para extraer los dos caracteres de la derecha utilizaremos la función RIGHT, de forma que la versión final de la expresión sería:

ShipDateKey =

YEAR(Sales[Ship Date]) &

RIGHT("0" & MONTH(Sales[Ship Date]); 2) &

RIGHT("0" & DAY(Sales[Ship Date]); 2)

El resultado, esta vez correcto, sería el mostrado en la siguiente imagen:

Si utilizásemos la función FORMAT, el código quedaría de la siguiente forma:

ShipDateKey =

YEAR(Sales[Ship Date]) &

FORMAT(MONTH(Sales[Ship Date]); "00") &