LASTDATE

Cálculo de totales acumulados

admin — Mon, 03 Dec 2018 19:19:03 +0000

Cálculo de totales acumulados admin Lun, 03/12/2018 - 20:19

Un escenario frecuente es aquel en el que queremos calcular el total acumulado, incluyendo todos los datos hasta una cierta fecha y no solo los implicados en el contexto de filtro actual. Por ejemplo, si suponemos la existencia de una tabla de ventas Sales que contiene una columna Amount con la cifra de ventas, podríamos definir una medida que calculase la suma de esta columna con la siguiente expresión DAX:

Sales = SUM(Sales[Amount])

Lógicamente, esta medida se va a adaptar al contexto de filtro, por lo que si la llevamos a una matriz en la que se esté desagregando las ventas por año:

...vemos que, para cada año, la cifra de ventas mostrada incluye solo las ventas de dicho año.

Lo que querríamos sería que, en cada evaluación de la medida, el período temporal considerado comenzase el primer día para que el hubo ventas (supongamos que el 1 de enero de 2015) y se extendiese hasta la última fecha del "período actual". Por ejemplo, en la cifra correspondiente al año 2018 el período actual es el correspondiente a los 365 días de dicho año. Pues bien, para el cálculo del acumulado para dicho año querríamos que se considerase el período comprendido entre el 1 de enero de 2015 y el 31 de diciembre de 2018. Es decir, escrito en pseudo-código:

Accumulated sales =
CALCULATE(
[Sales],
Período entre la primera fecha disponible y la última fecha del contexto actual
)

El período en cuestión puede calcularse usando la función DATESBETWEEN que devuelve el conjunto de fechas entre dos dadas. Si el calendario está contenido en la tabla Calendar, tendríamos, por lo tanto, que codificar la siguiente medida:

Accumulated sales =
CALCULATE(
[Sales],
DATESBETWEEN(
'Calendar'[Date],
Primera fecha disponible,
Última fecha del contexto actual
)
)

Ahora bien, es el cálculo de esas dos fechas lo que resulta más complejo, pues queremos que la primera fecha ("Primera fecha disponible") sea absoluta y haga referencia a la primera fecha disponible en el calendario, mientras que la segunda ("Última fecha del contexto actual") queremos que se adapte al contexto.

Para la obtención de la primera fecha disponible en el calendario deberemos asegurarnos de que no se están aplicando filtros al mismo, para lo que podemos usar la función ALL (lo que va a devolver una tabla). Y para la extracción de la primera fecha disponible de dicha tabla no podemos usar la función MIN pues ésta exige una columna como argumento, de forma que tendremos que usar la función FIRSTDATE, que sí acepta una tabla como argumento y devuelve otra tabla (con la fecha más antigua disponible), tabla que podemos pasar a la función CALCULATE como argumento de filtro:

FIRSTDATE(ALL(Sales[Order Date]))

Para el cálculo de la última fecha del contexto actual no tenemos más que utilizar la función MAX pasando como argumento la columna temporal que está desagregando nuestro objeto visual: la columna 'Calendar'[Date]. Es decir, la última fecha del contexto actual vendría dada por:

MAX('Calendar'[Date])

Es decir, la expresión

DATESBETWEEN(
    'Calendar'[Date],
    FIRSTDATE(ALL(Sales[Order Date])),
    MAX('Calendar'[Date])
)

...va a devolver el conjunto de fechas del calendario entre la más antigua disponible y la última implicada en el contexto actual. Podemos escribir, por lo tanto, la medida que devuelve las ventas acumuladas:

Accumulated sales =
CALCULATE(
    [Sales],
    DATESBETWEEN(
        'Calendar'[Date],
        FIRSTDATE(ALL(Sales[Order Date])),
        MAX('Calendar'[Date])
    )
)

Si quisiéramos utilizar variables para hacer más legible el código, podríamos crear dos variables, __firstdate y __lastDate conteniendo las dos fechas implicadas en el código anterior:

Accumulated sales =
VAR __firstDate = FIRSTDATE(ALL(Sales[Order Date]))
VAR __lastDate = MAX('Calendar'[Date])
RETURN
    CALCULATE(
        [Sales],
        DATESBETWEEN(
            'Calendar'[Date],
            __firstDate,
            __lastDate
        )
    )

Ahora, si llevamos la medida anterior a nuestra matriz, comprobamos que se están acumulando las ventas tal y como queríamos:

Y, por supuesto, si mostramos la matriz desagregada por cualquier otro nivel de nuestra jerarquía temporal, por trimestres, por ejemplo, el cálculo de las ventas acumuladas sigue realizándose correctamente:

Funciones DAX involucradas

Dificultad

Intermedia

Cálculo de una métrica a principio de cada mes

admin — Fri, 31 Jul 2020 06:10:13 +0000

Cálculo de una métrica a principio de cada mes admin Vie, 31/07/2020 - 08:10

En este escenario partimos de una tabla en la que se incluye información de los cambios de una cierta métrica por día. Por ejemplo, supongamos que se trata de las variaciones en la cantidad de cierto producto que hay en nuestro almacén. En este ejemplo la tabla se llama data y los dos campos que contiene son Fecha y Movimientos:

Obsérvese que la tabla incluye el último día del año 2019 aun cuando en este escenario queremos trabajar únicamente con el año 2020. Explicaré más adelante el motivo de comenzar la tabla por esta fecha.

El objetivo es calcular el estado de nuestro almacén a comienzo de cada mes (o de cada trimestre, o de cada año).

Para esto, tras leer los datos desde Power BI vamos a calcular una medida base que simplemente sume el campo Movimientos (para el contexto en el que nos encontremos en cada momento):

Quantity = SUM(data[Movimientos])

Hacemos esto para evitar tener que sumar dicho campo cada vez que necesitemos realizar este cálculo en futuras medidas.

Ahora podemos calcular el total acumulado de nuestros movimientos. Para esto vamos a crear una medida que sume Quantity desde el comienzo de los tiempos hasta "la fecha actual" (hasta la fecha máxima de cada contexto de cálculo). Todas las funciones DAX de inteligencia de tiempo requieren un calendario que sirva de referencia. Si tenemos una tabla con este calendario, estupendo. Si no, podemos crear una tabla calculada con la función CALENDARAUTO. Supongamos que llamamos a esta nueva tabla Calendar:

Calendar = CALENDARAUTO()

Una vez creada esta tabla no debemos olvidar crear una relación entre el recién creado campo Calendar[Date] y el campo Data[Fecha].

La medida que calcula el acumulado de nuestra medida Quantity (acumulado "hasta la fecha actual") es la siguiente:

Accumulated Quantity =
CALCULATE(
[Quantity],
DATESBETWEEN(
'Calendar'[Date],
FIRSTDATE(ALL('Calendar'[Date])),
LASTDATE('Calendar'[Date])
)
)

Básicamente estamos recalculando la medida Quantity (para lo que usamos la función CALCULATE) en un nuevo contexto: aquel formado por todas las fechas entre la primera que encontremos en el calendario (usando la función FIRSTDATE) y la última fecha "del contexto actual" (usando la función LASTDATE). Obsérvese el uso de la función ALL como argumento de FIRSTDATE: es lo que nos permite asegurar que estamos extrayendo el primer día de todo el calendario, y no el primer día del contexto actual.

Podemos crear una tabla en el lienzo de Power BI para ver el resultado hasta ahora:

A la tabla anterior se ha llevado el campo Calendar[Date] y las medidas Quantity y Accumulated Quantity, y, tal y como se muestra en la imagen, se ha filtrado de forma que solo muestre fechas a partir del 1 de enero de 2020.

Por último, no tenemos más que calcular, para cada fecha, el valor de la medida con el acumulado el primer día del mes correspondiente. Para esto podemos usar la función OPENINGBALANCEMONTH (o las funciones equivalentes OPENINGBALANCEQUARTER y OPENINGBALANCEYEAR si quisiéramos calcular dicho acumulado el primer día de cada trimestre o de cada año):

Quantity First Day of Month =
OPENINGBALANCEMONTH(
[Accumulated Quantity],
'Calendar'[Date]
)

Con esta medida estamos asociando a cada fecha (a cada contexto temporal, en realidad, sea de un día o no) la cifra de Accumulated Quantity del primer día del mes al que pertenece dicha fecha. Si llevamos esta medida a nuestra tabla obtenemos el siguiente resultado:

En la imagen anterior (que solo muestra la tabla entre el 1 de enero y el 5 de febrero) vemos que a cualquier día del mes de enero se asocia el valor 0 (acumulado a principio de dicho mes) y que a cualquier día de febrero se asocia el valor 21 (acumulado a principio de dicho mes). Y éste es el motivo de haber comenzado nuestra tabla de movimientos por el día 31 de diciembre de 2019: la función OPENINGBALANCEMONTH devuelve, en realidad, el valor de la métrica de que se trate antes del primer día del mes correspondiente -lo que tiene mucha lógica-: si el primer día de mi tabla (supongamos que es el 1 de enero) tengo un incremento de +2 (por ejemplo), la cifra acumulada a principio de dicho mes era de 0 (la cifra correspondiente al final del 31 de diciembre). De igual forma, si a finales de enero el total acumulado era de 21, con independencia del incremento que se produzca el 1 de febrero, el total acumulado a principios de febrero era de 21 (es decir, la cifra del último día de enero).

Si no hubiésemos incluido la fecha del 31 de diciembre, todos los días de enero habrían recibido como total acumulado a principio de mes el valor 127, que es la suma total de la columna Quantity, sencillamente porque no habría un día del mes anterior para hacer el cálculo y DAX, por diseño, consideraría toda la tabla.

Funciones DAX involucradas

Cálculo de la frecuencia de compra de los clientes

admin — Mon, 14 Oct 2019 10:50:28 +0000

Cálculo de la frecuencia de compra de los clientes admin Lun, 14/10/2019 - 12:50

En este escenario partimos de un listado de clientes:

...y de una tabla de compras de cada uno de ellos:

El objetivo es obtener un listado de clientes en el que se muestre el número de días (por ejemplo, podría ser otro período) entre compras. Para hacer el escenario sencillo los clientes reciben como nombre "Cliente x", siendo x el número de compras realizadas (de esta forma, el Cliente 0 no ha realizado ninguna, el Cliente 1 ha realizado una, etc.), y la frecuencia de compra en días para cada cliente coincide también con x. Así, el cliente 2 realizó una primera compra el 3 de enero, y una segunda dos días más tarde, el 5 de enero.

Una vez hemos asegurado que el modelo de datos incluye las relaciones adecuadas (incluyendo una relación entre la tabla de ventas y el necesario calendario), podemos crear una tabla calculada que, usando la función SELECTCOLUMNS, extraiga el listado de clientes y agregue la información necesaria. Partimos, por lo tanto, de la siguiente expresión DAX que define esta primera versión de nuestra tabla de resultados:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre]
)

Aunque podríamos calcular directamente la frecuencia de compra para cada uno de ellos, hagámoslo paso por paso, incluyendo una columna adicional para cada uno de los datos que necesitamos.

Si entendemos por frecuencia de compra el número de días transcurridos entre la primera compra y la última dividido entre el número de compras realizadas, en primer lugar sería preciso calcular las fechas de primera y de última compra por cliente, para lo que vamos a recurrir a las funciones FIRSTDATE y LASTDATE:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre];
"Primera compra"; FIRSTDATE(Calendario[Fecha]);
"Última compra"; LASTDATE(Calendario[Fecha])
)

El cálculo del rango de días entre ambas fechas se reduce a una sencilla resta, que realizaremos usando la función DATEDIFF, función que nos permite especificar el período a considerar -días, en nuestro ejemplo-:

Debemos entender que estamos realizando un enfoque un tanto ingenuo del problema al presuponer que el cliente existe como tal desde su primera compra y solo hasta la última. Más realista sería considerar como comienzo del período el día en el que el cliente "se dio de alta como tal", hubiese realizado o no una compra, y/o considerar como fin del período el día actual, por ejemplo.

Considérese también que, al crearse la tabla calculada en un entorno de contexto de fila, para cada cliente se extrae la información de la tabla remota relacionada con él. Así, cuando se está calculando la primera fecha de compra para el cliente X, la expresión

FIRSTDATE(Calendario[Fecha])

...filtra el campo Fecha de la tabla Calendario de forma que solo incluya las fechas para las que existen compras asociadas al cliente que corresponda.

El siguiente paso es contar el número de compras por cliente, para lo que podemos extraer la tabla Ventas (una vez filtrada por el contexto, para lo que usaremos la función RELATEDTABLE) y contar el número de filas que tiene con COUNTROWS:

Por último queda lo más sencillo, que es dividir el rango de fechas entre el número de compras, para lo que recurriremos a la función DIVIDE:

Frecuencia de compra =
SELECTCOLUMNS(
Clientes;
"Nombre"; Clientes[Nombre];
"Primera compra"; FIRSTDATE(Calendario[Fecha]);
"Última compra"; LASTDATE(Calendario[Fecha]);
"Rango"; DATEDIFF(FIRSTDATE(Calendario[Fecha]); LASTDATE(Calendario[Fecha]); DAY);
"Nº de compras"; COUNTROWS(RELATEDTABLE(Ventas));
"Frecuencia de compra"; DIVIDE(
DATEDIFF(FIRSTDATE(Calendario[Fecha]); LASTDATE(Calendario[Fecha]); DAY);
COUNTROWS(RELATEDTABLE(Ventas))
)
)

Comprobamos que, en esta primera versión de la expresión, si un cliente no ha realizado ninguna compra se muestra un BLANK, y si ha realizado una única compra de devuelve una frecuencia de 1. Podríamos completar nuestro DIVIDE con alguna función lógica que realizase un cálculo u otro en función del número de compras y, de esta forma, gestionar estas excepciones.

Puede descargarse el fichero Excel y el informe Power BI resultante aquí.

Funciones DAX involucradas

Dificultad

Intermedia

Cálculo de la anterior fecha de compra para cada compra de cada cliente

admin — Sat, 06 Jul 2019 18:23:28 +0000

Cálculo de la anterior fecha de compra para cada compra de cada cliente admin Sáb, 06/07/2019 - 20:23

Partimos de una tabla de ventas ("Movements") en la que figura la fecha de venta, el identificador del usuario y el importe de venta:

Nuestro objetivo es añadir una nueva columna en la que se muestre la última compra del mismo cliente. Al recorrerse la tabla creándose el nuevo campo se creará para cada fila el contexto de fila asociado, lo que nos da acceso a los campos de la fila. Concretamente, la función EARLIER nos permite acceder al identificador del cliente y a la fecha, de forma que podemos calcular el subconjunto de la tabla que contiene las compras del cliente actual anteriores a la fecha actual con la siguiente expresión:

FILTER(
   Movements;
   Movements[Customer Id] = EARLIER(Movements[Customer Id]) &&
   Movements[Order Date] < EARLIER(Movements[Order Date])
)

Una vez calculado este subconjunto, podemos extraer la última fecha muy fácilmente usando la función LASTDATE, función que devuelve una tabla con la última fecha del contexto actual. Usada como argumento de CALCULATE y añadiendo como filtro el subconjunto calculado, podemos extraer la última fecha del conjunto (es decir, la última fecha de compra antes de la actual):

Last Purchase =
CALCULATE(
LASTDATE(Movements[Order Date]);
FILTER(
Movements;
Movements[Customer Id] = EARLIER(Movements[Customer Id]) &&
Movements[Order Date] < EARLIER(Movements[Order Date])
)
)

Recordemos que, aunque la función LASTDATE devuelve una tabla, el resultado puede ser usado como un escalar allí donde se requiera una simple fecha. El resultado obtenido es el siguiente:

Podemos confirmar que el cálculo es correcto si llevamos a una visualización tipo tabla el identificador de usuario, el campo Order Date y el campo recién creado Last Purchase, filtrando el identificador de usuario (usando una segmentación, por ejemplo) y ordenando la tabla creada según el campo Order Date:

Vemos cómo la fecha de última compra coincide con la anterior.

Funciones DAX involucradas

Obtención de la fecha de la primera y última venta de cada vendedor

admin — Mon, 08 Apr 2019 09:50:20 +0000

Obtención de la fecha de la primera y última venta de cada vendedor admin Lun, 08/04/2019 - 11:50

En este sencillo escenario partimos de los siguientes datos:

Tabla de vendedores:

Tabla de ventas:

El objetivo es crear una tabla calculada en la que se incluya el nombre del vendedor y las fechas de su primera y última venta. Comencemos creando la tabla con los nombres, para lo que vamos a usar la función SELECTCOLUMNS:

Listado vendedores = SELECTCOLUMNS(
Vendedores;
"Nombre"; Vendedores[Nombre Vendedor]
)

Añadamos ahora la columna con la primera fecha de venta. Podríamos pensar en la necesidad de extraer mediante la función RELATEDTABLE el subconjunto de la tabla de ventas asociada a cada fila de nuestra tabla (tal y como hacemos en el escenario de Creación de una tabla con las ventas medias por vendedor) pero la función FIRSTDATE, tal y como podemos leer en la documentación, devuelve la primera fecha en el contexto actual, lo que supone el contexto de fila definido por cada vendedor, en nuestro caso, lo que hace innecesario el uso de la mencionada función RELATEDTABLE. Basta con usar FIRSTDATE de la siguiente forma:

Listado vendedores = SELECTCOLUMNS(
Vendedores;
"Nombre"; Vendedores[Nombre Vendedor];
"Primera venta"; FIRSTDATE(Ventas[Fecha])
)

Vemos que las fechas son distintas, lo que ya nos indica que el cálculo de FIRSTDATE se realiza en contextos diferentes para cada fila. En todo caso comprobamos mediante una inspección ocular de la tabla de ventas que las fechas mostradas son las correctas.

La adición de la última fecha de venta es análoga, utilizando la función LASTDATE:

Listado vendedores = SELECTCOLUMNS(
Vendedores;
"Nombre"; Vendedores[Nombre Vendedor];
"Primera venta"; FIRSTDATE(Ventas[Fecha]);
"Última venta"; LASTDATE(Ventas[Fecha])
)

Funciones DAX involucradas

SELECTCOLUMNS

FIRSTDATE

LASTDATE

Análisis de la evolución de las ventas con una ventana de 14 días

admin — Fri, 04 Jan 2019 14:04:36 +0000

Análisis de la evolución de las ventas con una ventana de 14 días admin Vie, 04/01/2019 - 15:04

En este escenario partimos de una tabla de ventas (Sales) en la que se indica, entre otros campos, la fecha y el importe de venta (SalesAmount). La medida [Sales] suma este última columna.

El objetivo es llevar a una gráfica de líneas las ventas acumuladas durante las dos semanas previas para todas las fechas del calendario. Lo que necesitamos es calcular la medida Sales para el período de dos semanas de duración que termina en la fecha que se esté considerando en cada momento, es decir, en pseudo-código sería:

Fortnight sales = CALCULATE(

[Sales];

Período-de-dos-semanas-terminando-en-la-fecha-actual

)

Como puede verse, utilizaremos la función CALCULATE para evaluar la medida Sales en el período de interés.

Para el cálculo del período de dos semanas que terminan en la fecha siendo considerada utilizaremos la función DATESINPERIOD, función que nos permite especificar la fecha de inicio de cálculo, el intervalo a añadir o restar (días en nuestro caso) y el número de intervalos a añadir o restar (14 en nuestro caso). Podríamos describir el período de interés de la siguiente forma:

Período-de-dos-semanas-terminando-en-la-fecha-actual =

DATESINPERIOD(

'Calendar'[Date];

LASTDATE('Calendar'[Date]);

-14;

DAY)

En nuestro ejemplo, la fecha de partida será la última del contexto (o la primera, pues se determinará según el contexto de fila ya que vamos a realizar nuestro cálculo para cada uno de los días por separado).

Podemos, por lo tanto, definir la medida de la siguiente forma:

Fortnight sales = CALCULATE(

[Sales];

DATESINPERIOD(

'Calendar'[Date];

FIRSTDATE('Calendar'[Date]);

-14;

DAY

)

Si llevamos a una tabla la columna del calendario conteniendo las fechas ('Calendar'[Date]) y la recién creada medida, obtenemos el siguiente resultado:

Puede comprobarse como, lógicamente, los 13 primeros días muestran acumulados parciales al no existir fechas anteriores al 1 de julio de 2001.

Si llevamos estos mismos campos a un gráfico de líneas, el resultado es el siguiente:

Funciones DAX involucradas