Cálculo del número de días entre compras

admin — Tue, 02 Jul 2019 14:23:33 +0000

Calculation of the number of days between purchases admin Tue, 07/02/2019 - 16:23

We start from a list of sales (Sales) in which, for example, the customer identifier and the dates of the purchases are indicated:

The objective is to add to this table a column that indicates the number of days elapsed since the previous purchase (earlier in time, since nothing assures us that the order of the data in the original table is chronological, and we already know that Power BI neither ensures the order of the rows).

The resolution of this scenario is not easy. Although it could be solved in a single expression, its resolution is presented below step by step. The phases involved are the following:

It is necessary to obtain, for each purchase date of customer X, the date of the previous purchase.
The previous purchase date is the highest date of all customer X's purchases (except for the purchase we are analyzing, of course).
We can obtain all the previous purchases of customer X by cross-joining the table with itself, taking as common field the one corresponding to the customer's identifier and considering in the right table (see the documentation of the GENERATE function) only the dates before the purchase date being considered in the left table. Thus, for example, for the purchase that appears in the third line of the previous image (corresponding to customer 1, dated January 21, 2019), a cross joining with the same table in the aforementioned conditions would return a row for the combination of row 3 and row 1 (same customer and previous date) and another for the combination of row 3 and row 2 (again, same customer and previous date).

Finally, once the table mentioned in point 1 has been obtained, it would be enough to calculate the difference between each purchase date and the date of the last purchase.

Let's do it step by step.

First we want to obtain, for each row (that is, for each purchase), the set of previous purchases of the same customer. This, as mentioned, can be achieved with a cross join that allows us to specify the conditions of the join, that is, with the GENERATE function. As this function requires that the tables involved in the combination have fields with different names, we are going to modify the names of the fields of the second copy with the SELECTCOLUMNS function, adding a "_" symbol at the end of the names:

SelfJoin =
GENERATE(
Sales;
FILTER(
SELECTCOLUMNS(
Sales;
"Customer_"; Sales[Customer];
"Purchase Date_"; Sales[Purchase Date]
);
[Purchase Date_] < Sales[Purchase Date] && Sales[Customer] = [Customer_]
)
)

As we can see, we are obtaining the cross join by imposing the condition that the customer identifier is the same, and that the dates in the column on the right are lower than the date considered in each of the rows on the left (for simplicity, we are assuming that the same customer will not make two purchases on the same day).

Note that the records in the first table for which there are no records in the second that meet the imposed conditions do not appear (that is, in the table that we have just created, only purchase dates for which there is a previous purchase are included).

Obtaining, from here, the date before each purchase is easy: just group (with the GROUPBY function) by customer and purchase date (Customer and Purchase Date fields) and select the maximum value (of each group) of the field Purchase Date_ :

LastPurchases =
GROUPBY(
SelfJoin;
SelfJoin[Customer];
SelfJoin[Purchase Date];
"Last Purchase"; MAXX(
CURRENTGROUP();
SelfJoin[Purchase Date_]
)
)

Now comes a somewhat complicated process: as the table only includes purchase dates for which there is a previous purchase, if we want all the original dates to appear in the final result we would have to perform a left outer join between the original date table and the new one. For this we would have to use the NATURALLEFTOUTERJOIN function, but this function requires that the tables to be joined have the same lineage (they come from the same source), which is not true in our case. As explained in the documentation for this function, it is possible to solve this problem by adding an empty text string to the end of the names:

Purchase and Last Purchase =
NATURALLEFTOUTERJOIN(
SELECTCOLUMNS(
Sales;
"Customer"; Sales[Customer] & "";
"Purchase Date"; Sales[Purchase Date] & ""
);
SELECTCOLUMNS(
LastPurchases;
"Customer"; LastPurchases[SelfJoin_Customer] & "";
"Purchase Date"; LastPurchases[SelfJoin_Purchase Date] & "";
"Last Purchase"; LastPurchases[Last Purchase]
)
)

Finally, to calculate the number of days since the last purchase, simply add a new column that returns the difference (only if there is a last purchase):

Days since last purchase =
ADDCOLUMNS(
'Purchase and Last Purchase';
"# days";
VAR
NumberOfDays =
'Purchase and Last Purchase'[Purchase Date] -
'Purchase and Last Purchase'[Last Purchase]
RETURN
IF(
ISBLANK('Purchase and Last Purchase'[Last Purchase]);
BLANK();
NumberOfDays
)
)

To return the day difference, we use the IF function to confirm if the value of the field corresponding to the last purchase is a BLANK or not, for which we use the ISBLANK function.

DAX functions involved

Difficulty

High

Agregación de dos tablas con la misma estructura

admin — Wed, 10 Apr 2019 08:58:12 +0000

Aggregation of two tables with the same structure admin Wed, 04/10/2019 - 10:58

A frequent and easy to solve scenario is one in which we find ourselves with two tables with the same structure that we want to add according to some field. Let's see what it would be like. We assume that we have already obtained the data and we have loaded in Power BI the two tables that, in this case, contain sales information:

In this scenario we want to get the total sales by seller ("Id Vendedor" field). We are going to do it in two phases:

Union of the previous tables
Aggregation of the complete table to show the sales ("Precio final" field) according to the field that identifies each seller

For the first step we are going to use the UNION function. However, we are not going to join the tables directly because, as we see in the previous images, despite having the same structure (and, in the query editor, appearing with the columns in the same order) when imported into Power BI columns are not displayed in the same order (probably due to a software bug that has been around since at least late 2017). That is why we are going to apply the UNION function to the tables, specifying by hand the columns that interest us and the order that interests us, for which we will resort to the SELECTCOLUMNS function:

Ventas totales =
VAR
Tabla1 = SELECTCOLUMNS(
Ventas1;
"Vendedor"; Ventas1[Id Vendedor];
"PVP"; Ventas1[Precio final]
)
VAR
Tabla2 = SELECTCOLUMNS(
Ventas2;
"Vendedor"; Ventas2[Id Vendedor];
"PVP"; Ventas2[Precio final]
)
RETURN
UNION(Tabla1; Tabla2)

We have only selected the columns "Vendedor" ("seller") and "Precio final" ("Final price", with the name "PVP") but we could have selected other columns as well.

Now, for the second step, we use the SUMMARIZE function to add the above table:

Ventas totales por vendedor =
SUMMARIZE(
'Ventas totales';
'Ventas totales'[Vendedor];
"Ventas"; SUM('Ventas totales'[PVP]
)
)

DAX functions involved

Difficulty

Intermediate